Create a New Workbook and Save As? Help

[MichaelRSnow]

Hi Help needed.

Been reviewing code for ages now and none seem to be that simple, I'm trying to, via a Command Button, Copy & Paste Values of Sheet1 in the existing workbook to a New Workbook and then open SAVE AS so it can be saved where the user wants it to be and called what ever they want to call it?

If anyone has some code for this it will be very much appreciated?

 

[Richard Schollar]

Hi

the code executed by the button could look like this:

Sub copy_sheet1()
 
Dim ws As Worksheet
 
Set ws = Worksheets("Sheet1")  'amend as required
 
Workbooks.Add
ws.UsedRange.Copy
Activesheet.Range("A1").PasteSpecial xlPasteValues
 
With Application.FileDialog(msoFileDialogSaveAs)
    .InitialFileName = Application.DefaultFilePath
    .AllowMultiSelect = False
    If .Show = -1 Then .Execute
End With
End Sub

 

[MichaelRSnow]

Works great, 1 small thing...what if some of the cells were hidden in the orginal workbook, this current method doesn't keep the copied cells hidden. Can this be achieved?

 

[Richard Schollar]

If you didn't want to copy the hidden cells you could do this:

Sub copy_sheet1()
 
Dim ws As Worksheet
 
Set ws = Worksheets("Sheet1")  'amend as required
 
Workbooks.Add
ws.UsedRange.SpecialCells(xlCellTypeVisible).Copy
Activesheet.Range("A1").PasteSpecial xlPasteValues
 
With Application.FileDialog(msoFileDialogSaveAs)
    .InitialFileName = Application.DefaultFilePath
    .AllowMultiSelect = False
    If .Show = -1 Then .Execute
End With
End Sub

or if you want to copy them and have them hidden then try this (note I doubt whether you'll be able to do this if you have any merged cells on the sheet):

Sub copy_sheet1()
 
Dim ws As Worksheet
 
Set ws = Worksheets("Sheet1")  'amend as required
 
Workbooks.Add
ws.Cells.Copy
Activesheet.Range("A1").PasteSpecial
Activesheet.Range("A1").PasteSpecial xlPasteValues
 
With Application.FileDialog(msoFileDialogSaveAs)
    .InitialFileName = Application.DefaultFilePath
    .AllowMultiSelect = False
    If .Show = -1 Then .Execute
End With
End Sub

 

[MichaelRSnow]

Works like a charm, thanks Richard