Create msgbox to confirm before Outlook closes

zoso · Nov 28, 2005

Hi there!

I have the following code:

Code:

Private Sub Application_Quit()
    Dim Response As Integer
    Dim Title As String
    Dim Message As String

   Title = "Confirm"
   Message = "Do you really want to quit Outlook?"
   Response = MsgBox(Message, vbYesNo, Title)
   If Response = vbNo Then
       ???????????????
   End If
End Sub

What I'm after is some code in place of the ???????? so that Outlook remains open.

Hope you can help - and thanks!

NateO · Nov 28, 2005

Hello,

I don't understand which part of your code could close Outlook?

If it's hidden, just make it visible...

zoso · Nov 28, 2005

Hi Nate - thanks for trying to help me out here!

All I'm trying to do is stop myself closing Outlook by mistake and creating a yes/no msgbox to do so.

If I say 'Yes', then Outlook closes, if 'No' then Outlook stays open.

I hope that's clear?

Thanks again!

Zack Barresse · Nov 29, 2005

You can't do this in Outlook, the Object Model does not support it. This is known by MS and has been requested in future versions. Whether or not they add this type of functionality is not yet known (by myself anyway), but I certainly hope it does get done.

I'm actually facing the same issue. I'm looking into disabling the exit button, but it's proving to be quite difficult. The commandbars object is not like other office application objects, as it's located in a different object altogether (Application.ActiveExplorer).

zoso · Nov 29, 2005

Zack - thanks a lot for replying.

From my point of view Excel's coding is light years ahead of Outlook and you could be fooled into thinking it was not part of the same 'Office Family' :wink:

Zack Barresse · Nov 29, 2005

It is light years ahead of Outlooks Object Model. Programming in Outlook - and Publisher even - is quite the headache. They are just so under-developed it's not even funny.

As I said earlier, I'm working on this issue as well. If I get anything of substance I'll post it here for you. But I wouldn't hold my breath.

zoso · Nov 29, 2005

Zack - thanks, and good luck!

Zack Barresse · Nov 29, 2005

Zoso, I recommend you download OutlookSpy. It's probably the best way to view the Object Model and view any attributed properties along with it.

As I don't think there is any way we can stop somebody from closing outlook, this brought my search into another path: disable the Exit and close button. Of course this won't stop somebody from ending the OUTLOOK.EXE process at all, but it's a start.

To disable the Exit from the File menu, run this code in your ThisOutlookSession module ...

Option Explicit

Private Sub Application_Startup()
 With Application.ActiveExplorer.CommandBars.Item("Menu Bar")
 .Controls.Item("&File").Controls.Item("E&xit").Enabled = False
 End With
End Sub

What I am thinking of doing, as I want (as administrator) the right to close outlook, but in order to do this I think a password should be supplied. I'm working right now on two things, 1) creating a shortcut key with a password structure to allow administrators only to exit the program, and 2) disabling the 'X' close button. For the second, there is no way to do this with VBA, so I'm researching some API to see if I can retro-fit it to my cause.

Will post when/if I have more. Good luck!

zoso · Nov 29, 2005

Excellent Zack, thanks a lot for keeping me posted!

Zack Barresse · Nov 29, 2005

Okay, delved a little more (making some decent progress today). What I've done is decided that I wanted a little more interactivity between myself and Outlook, and I felt the best way to do that was to go the custom menu route. So this code will give you a custom menu called 'Admin' after your Help menu, which has two options, Enable Exit and Disable Exit.

This requires changing some code in your ThisOutlookSession module and creating 2 new Standard Modules.

In ThisOutlookSession paste:

Option Explicit

Private Sub Application_Startup()

 Call DisableExit
 Call CreateMenu

End Sub

In module Mod_Menu (just my naming convention:

Option Explicit

Public Const APP_NAME As String = "Admin"

Sub CreateMenu()

 Dim CB As CommandBar
 Dim Menu As CommandBarPopup
 Dim Item As CommandBarButton
 Dim Pos As Long

 Call DeleteMenu

 Set CB = Application.ActiveExplorer.CommandBars.Item("Menu Bar")
 Pos = CB.Controls.Count + 1

'Main Menu
 Set Menu = CB.Controls.Add(Type:=msoControlPopup, before:=Pos)
 Menu.Caption = APP_NAME
 Menu.BeginGroup = True

'Menu Items
 Set Item = Menu.Controls.Add(Type:=msoControlButton)
 With Item
 .Caption = "&Enable Exit"
 .FaceId = 1 'set as desired
 .OnAction = "EnableExit"
 End With
 Set Item = Menu.Controls.Add(Type:=msoControlButton)
 With Item
 .Caption = "&Disable Exit"
 .FaceId = 1 'set as desired
 .OnAction = "DisableExit"
 End With

 Set Item = Nothing
 Set Menu = Nothing
 Set CB = Nothing

End Sub

Sub DeleteMenu()
 On Error Resume Next
 Application.ActiveExplorer.CommandBars.Item("Menu Bar").Controls(APP_NAME).Delete
End Sub

In module Mod_Routines (just my naming convention:

Option Explicit

Public Const PWD As String = "admin"

Public Sub DisableExit()
 Dim tmp As String
 tmp = InputBox("Enter Password:", "Password")
 If Len(tmp) = 0 Then Exit Sub
 If tmp <> PWD Then
 MsgBox "Sorry! Wrong password. Try again.", vbInformation, "ERROR!"
 Exit Sub
 End If
 Application.ActiveExplorer.CommandBars.Item("Menu Bar" _
 ).Controls.Item("&File").Controls.Item("E&xit").Enabled = False
 MsgBox "File | Exit is now disabled!", vbExclamation
End Sub

Public Sub EnableExit()
 Dim tmp As String
 tmp = InputBox("Enter Password:", "Password")
 If Len(tmp) = 0 Then Exit Sub
 If tmp <> PWD Then
 MsgBox "Sorry! Wrong password. Try again.", vbInformation, "ERROR!"
 Exit Sub
 End If
 Application.ActiveExplorer.CommandBars.Item("Menu Bar" _
 ).Controls.Item("&File").Controls.Item("E&xit").Enabled = True
 MsgBox "File | Exit is now enabled!", vbExclamation
End Sub


Works great for me in OL 2003, do not have any previous versions here for me to test on. I'm working on that API call to disable the X button - still not sure if that can be done or not though.

Hope this helps you Zoso.

Create msgbox to confirm before Outlook closes

zoso

Well-known Member

Excel Facts

NateO

Legend

zoso

Well-known Member

Zack Barresse

MrExcel MVP

zoso

Well-known Member

Zack Barresse

MrExcel MVP

zoso

Well-known Member

Zack Barresse

MrExcel MVP

zoso

Well-known Member

Zack Barresse

MrExcel MVP

Similar threads

Forum statistics

Share this page

Create msgbox to confirm before Outlook closes

Well-known Member

Excel Facts

Legend

Well-known Member

MrExcel MVP

Well-known Member

MrExcel MVP

Well-known Member

MrExcel MVP

Well-known Member

MrExcel MVP

Similar threads

Forum statistics

Share this page

We've detected that you are using an adblocker.

Which adblocker are you using?

Disable AdBlock

Disable AdBlock Plus

Disable uBlock Origin

Disable uBlock