Creating chart with VBA

[FryGirl]

Hello all,

I can't seem to find this one. I tried the Application.wait, but not sure that will do it.

The routine below runs perfectly fine to draw the plots; however, is there a way to have one loop draw on the chart at a time instead of the entire loop running and then all the plots appear at the same time?

Sub DrawChart()
    Dim i As Long
    With ActiveChart
        .ChartType = xlXYScatter
      For i = 1 To 9
        With .SeriesCollection.NewSeries
          .XValues = Cells(i + 1, 1)
          .Values = Cells(i + 1, 2)
        End With
        Application.Wait (Now + TimeValue("00:00:02"))
      Next i
    End With
End Sub

 

[NdNoviceHlp]

Interesting. This seems to do it. Dave

 Dim i As Long
    With Sheets("Sheet1").ChartObjects(1).Chart
        .ChartType = xlXYScatter
      For i = 1 To 9
        With .SeriesCollection.NewSeries
          .XValues = Cells(i + 1, 1)
          .Values = Cells(i + 1, 2)
        End With
        Application.Wait (Now + TimeValue("00:00:01"))
        DoEvents
        Application.Wait (Now + TimeValue("00:00:01"))
      DoEvents
      Next i
    End With

 

[FryGirl]

That works great Dave. Thank you.

 

[NdNoviceHlp]

I have no idea why the code works like that and I really wasn't sure if it would work for U the same as it did for me. Thanks for posting your outcome. Dave

 

[NdNoviceHlp]

Hi again FryGirl. I had forgot some wisdom that Jon Peltier had provided. This code makes more sense to me and is likely more reliable across operating systems. I have a notion that the previous code may be dependent upon maybe both the cpu speed and/or XL version. HTH. Dave
ps. Thanks again Jon

Sub DrawChart()
 Dim i As Long, t As Double
    With Sheets("Sheet1").ChartObjects(1).Chart
        .ChartType = xlXYScatter
      For i = 1 To 9
        With .SeriesCollection.NewSeries
          .XValues = Cells(i + 1, 1)
          .Values = Cells(i + 1, 2)
        End With
'Jon's part
t = Timer
Do Until Timer - t > 1
  DoEvents
Loop
      Next i
    End With
End Sub

 

[FryGirl]

Hi Dave,

Interestingly enough, I too ran across this somewhere else and have implemented it. Thank you for the follow-up.