Ctrl+Printscreen via VBA

[Coley]

I have this code taken from a previous post which works perfectly.

Option Explicit

Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
Public Const VK_SNAPSHOT = &H2C

Sub PrintScreen()
keybd_event VK_SNAPSHOT, 0, 0, 0
End Sub

What i would really like, is to amend this so it only copies the Dialog boxes that are open (usually Keystroke Ctrl+PrintScreen).

Help would be appreciated

 

[Coley]

Apologies, Alt+Printscreen....

Coley

 

[BJungheim]

This appears to work:

Option Explicit

Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
Public Const VK_SNAPSHOT = &H2C

Sub PrintScreen()
keybd_event VK_SNAPSHOT, 1, 0, 0
End Sub

Note the value of bVk in the Sub.

 

[Coley]

Thanks for you're help. However, this only appears to copy a proportion of the Userform. The centre part.

 

[Jaafar Tribak]

Here is a demo that copies the Data Validation Dialoge Box...See if it works .

'\this is a routine to show how
'\to copy the DataValidation Dialog box
'\to the Clipboard. can be adapted to
'\copy any other dialog or active child window

Option Explicit

Private Declare Sub keybd_event Lib "user32.dll" _
(ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Declare Function SetTimer Lib "user32" _
(ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, _
ByVal lpTimerFunc As Long) As Long

Private Declare Function KillTimer Lib "user32" (ByVal hwnd As Long, _
ByVal nIDEvent As Long) As Long

Dim lTimerID As Long

Private Const KEYEVENTF_KEYUP = &H2
Private Const VK_SNAPSHOT = &H2C
Private Const VK_MENU = &H12


Private Sub TimerProc()
 
    '\we don't need the timer anymore
    KillTimer 0, lTimerID
    '\ press the ALT key
    keybd_event VK_MENU, 0, 0, 0
    '\ press the PrtSc key
    keybd_event VK_SNAPSHOT, 0, 0, 0
    '\ release the PrtSc key
    keybd_event VK_SNAPSHOT, 0, KEYEVENTF_KEYUP, 0
    '\ release the ALT key
    keybd_event VK_MENU, 0, KEYEVENTF_KEYUP, 0

End Sub


'run this test routine

Sub Copy_DataValidation_DialogBox()

    lTimerID = SetTimer(0, 0, 100, AddressOf TimerProc)
    Application.Dialogs(xlDialogDataValidation).Show

End Sub

Regards.

 

[Coley]

Works perfect. Thanks very much