custom column to row

[kambing_tempur]

Hi, I have a number of similarly formatted data but they are all in stacked together in 1 column, I want to move them so that each data has their own columns, it should be something like this:

1A		1A	2A	3A
1B		1B	2B	3B
1C		1C	2C	3C
2A
2B	==>
2C
3A
3B
3C

<tbody>
</tbody>

Does anyone have any idea? thanks in advance

 

[hiker95]

kambing_tempur,

With your raw data in worksheet Sheet1. You can change the raw data worksheet name in the macro.

With your raw data sorted/grouped by the text in column A.

Here is a macro solution, and, Function, for you to consider, based on your flat text display, and, it will adjust to the number of raw data rows, and, columns needed for the results.

Sample raw data, and, results:

Excel 2007
	A	B	C	D	E	F	G
1	1A		1A	1B	1C
2	1B		2A	2B	2C
3	1C		3A	3B	3C
4	2A		4A	4B	4C	4D
5	2B
6	2C
7	3A
8	3B
9	3C
10	4A
11	4B
12	4C
13	4D
14
Sheet1

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

1. Copy the below code, and, Function
2. Open your NEW workbook
3. Press the keys ALT + F11 to open the Visual Basic Editor
4. Press the keys ALT + I to activate the Insert menu
5. Press M to insert a Standard Module
6. Where the cursor is flashing, paste the code
7. Press the keys ALT + Q to exit the Editor, and return to Excel
8. To run the macro from Excel press ALT + F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.

Sub ReorgData()
' hiker95, 11/25/2016, ME977400
Dim r As Long, lr As Long, n As Long, nr As Long
Application.ScreenUpdating = False
With Sheets("Sheet1")   '<-- you can change the sheet name here
  lr = .Cells(Rows.Count, 1).End(xlUp).Row
  .Range("B1").Formula = "=GetDigits(A1)"
  .Range("B1").Copy .Range("B2:B" & lr)
  nr = 0
  For r = 1 To lr
    nr = nr + 1
    n = Application.CountIf(.Columns(2), .Cells(r, 2).Value)
    .Cells(nr, 3).Resize(, n).Value = Application.Transpose(.Range("A" & r & ":A" & r + n - 1))
    .Cells(r, 2).Resize(n).ClearContents
    r = r + n - 1
Next r
  .UsedRange.Columns.AutoFit
End With
Application.ScreenUpdating = True
End Sub
Function GetDigits(ByVal Text As String) As String
' Rick Rothstein, MrExcel MVP, 08/18/2011, ME572628
' http://www.mrexcel.com/forum/excel-questions/572628-extract-numbers-string.html
Dim X As Long
For X = 1 To Len(Text)
  If Not Mid(Text, X, 1) Like "#" Then Mid(Text, X) = " "
Next
GetDigits = Replace(Text, " ", "")
End Function

Before you use the macro, and, Function, with Excel 2007 or newer, save your workbook, Save As, a macro enabled workbook with the file extension .xlsm, and, answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.

Then run the ReorgData macro.

 

[Rick Rothstein]

Here is a macro solution, and, Function, for you to consider, based on your flat text display, and, it will adjust to the number of raw data rows, and, columns needed for the results.

Your macro appears to output the results transposed from what was asked for.

 

[Rick Rothstein]

Hi, I have a number of similarly formatted data but they are all in stacked together in 1 column, I want to move them so that each data has their own columns, it should be something like this:

Two questions...

1) Does your data really look like that (where the first character only distinguishes one group from another?

2) Do all of your groups always consist of the same number of rows (3 in the case of your example data) or can the number of rows in each group differ from the number of rows in other groups?

 

[hiker95]

Your macro appears to output the results transposed from what was asked for.

Rick Rothstein,

Thanks for that catch, and, I do not understand what I did???

 

[hiker95]

kambing_tempur,

With your raw data in worksheet Sheet1. You can change the raw data worksheet name in the macro.

With your raw data sorted/grouped by the text in column A.

Here is a corrected macro solution, and, Function, for you to consider, based on your flat text display, and, it will adjust to the number of raw data rows, and, columns needed for the results.

Sample raw data, and, results:

Excel 2007
	A	B	C	D	E	F	G
1	1A		1A	2A	3A	4A
2	1B		1B	2B	3B	4B
3	1C		1C	2C	3C	4C
4	2A					4D
5	2B
6	2C
7	3A
8	3B
9	3C
10	4A
11	4B
12	4C
13	4D
14
Sheet1

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

1. Copy the below code, and, Function
2. Open your NEW workbook
3. Press the keys ALT + F11 to open the Visual Basic Editor
4. Press the keys ALT + I to activate the Insert menu
5. Press M to insert a Standard Module
6. Where the cursor is flashing, paste the code
7. Press the keys ALT + Q to exit the Editor, and return to Excel
8. To run the macro from Excel press ALT + F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.

In your workbook, you can only have one copy of the GetDigits Function.

Sub ReorgData_V2()
' hiker95, 11/25/2016, ME977400
Dim r As Long, lr As Long, n As Long, nc As Long
Application.ScreenUpdating = False
With Sheets("Sheet1")   '<-- you can change the sheet name here
  lr = .Cells(Rows.Count, 1).End(xlUp).Row
  .Range("B1").Formula = "=GetDigits(A1)"
  .Range("B1").Copy .Range("B2:B" & lr)
  nc = 3
  For r = 1 To lr
    n = Application.CountIf(.Columns(2), .Cells(r, 2).Value)
    .Cells(1, nc).Resize(n).Value = .Range("A" & r & ":A" & r + n - 1).Value
    .Cells(r, 2).Resize(n).ClearContents
    r = r + n - 1
    nc = nc + 1
Next r
  .UsedRange.Columns.AutoFit
End With
Application.ScreenUpdating = True
End Sub
Function GetDigits(ByVal Text As String) As String
' Rick Rothstein, MrExcel MVP, 08/18/2011, ME572628
' http://www.mrexcel.com/forum/excel-questions/572628-extract-numbers-string.html
Dim X As Long
For X = 1 To Len(Text)
  If Not Mid(Text, X, 1) Like "#" Then Mid(Text, X) = " "
Next
GetDigits = Replace(Text, " ", "")
End Function

Before you use the macro, Function, with Excel 2007 or newer, save your workbook, Save As, a macro enabled workbook with the file extension .xlsm, and, answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.

Then run the ReorgData_V2 macro.

 

[Rick Rothstein]

kambing_tempur,

With your raw data in worksheet Sheet1. You can change the raw data worksheet name in the macro.

With your raw data sorted/grouped by the text in column A.

Here is a corrected macro solution, and, Function, for you to consider, based on your flat text display, and, it will adjust to the number of raw data rows, and, columns needed for the results.

If you are correct and the first character determines the members of each "group", then this macro should produce the same results as yours but without needing your attached function procedure (note that my code assume it is being executed with the data sheet as the active sheet)...

[table="width: 500"]
[tr]
	[td]Sub ReorgData_V3()
  Dim R As Long, C As Long, X As Long, FirstRow As Long, FirstChar As String, Data As Variant
  Data = Range("A1", Cells(Rows.Count, "A").End(xlUp).Offset(1))
  FirstChar = Left(Data(1, 1), 1)
  FirstRow = 1
  C = 1
  Application.ScreenUpdating = False
  For R = 2 To UBound(Data)
    If Left(Data(R, 1), 1) <> FirstChar Then
      C = C + 1
      Cells(1, C).Resize(R - FirstRow) = Application.Index(Data, Evaluate("ROW(" & FirstRow & ":" & R & ")"), Split("1"))
      FirstRow = R
      FirstChar = Left(Data(R, 1), 1)
    End If
  Next
  Application.ScreenUpdating = True
End Sub[/td]
[/tr]
[/table]