Custom Time Formatting

[mikebecker]

I'm entering hundreds of time entries from time studies.

I would like to enter times as: 091740
and formatting applied to show 09:17:40

Any solution? VBA or Formatting?

 

[Pollygirl]

Need to paste this in your active worksheet in visual basic, with activation "change" and set the format for the cells to the time style you want:



Private Sub Worksheet_Activate()

End Sub

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim TimeStr As String

On Error GoTo EndMacro
If Application.Intersect(Target, Range("e4:l2000")) Is Nothing Then
Exit Sub
End If
If Target.Cells.Count > 1 Then
Exit Sub
End If
If Target.Value = "" Then
Exit Sub
End If

Application.EnableEvents = False
With Target
If .HasFormula = False Then
Select Case Len(.Value)
Case 1 ' e.g., 1 = 00:01 AM
TimeStr = "00:0" & .Value
Case 2 ' e.g., 12 = 00:12 AM
TimeStr = "00:" & .Value
Case 3 ' e.g., 735 = 7:35 AM
TimeStr = Left(.Value, 1) & ":" & _
Right(.Value, 2)
Case 4 ' e.g., 1234 = 12:34
TimeStr = Left(.Value, 2) & ":" & _
Right(.Value, 2)
Case 5 ' e.g., 12345 = 1:23:45 NOT 12:03:45
TimeStr = Left(.Value, 1) & ":" & _
Mid(.Value, 2, 2) & ":" & Right(.Value, 2)
Case 6 ' e.g., 123456 = 12:34:56
TimeStr = Left(.Value, 2) & ":" & _
Mid(.Value, 3, 2) & ":" & Right(.Value, 2)
Case Else
Err.Raise 0
End Select
.Value = TimeValue(TimeStr)
End If
End With
Application.EnableEvents = True
Exit Sub
EndMacro:
Application.EnableEvents = True
End Sub

 

[xcellnoob]

or you could just set up a column beside it and enter in the top cell
=TIMEVALUE(TEXT(B1,"00\:00\:00"))
and copy all the way down.
Just make sure your formats are correct.

 

[mikebecker]

Both solutions work great.

I really like the VBA!!

Thanks.

 

[xcellnoob]

I like the VBA too; I just don't understand it. If things go wrong, I need to be able to understand why. Someday I'll get to VBA.