Delete adjacent columns

[doncarp]

I need to improve a portion of my macro that is supposed to delete two columns. When my estimating program exports to Excel there is a column named "Digitizer" and the next column does not have a header. Digitizer is not always in the same column. I need to find "Digitizer"and delete two columns. I thought I had it with this code, but today I had a case where there was some data in the column and I only deleted some cells, not the entire column.

Dim rng1 As Range
Set rng1 = Range(Range("A1:Z1").Find("Digitizer").Offset(0, 1), Range("A1:Z1").Find("Digitizer").End(xlDown))
rng1.Select
Selection.Delete Shift:=xlToLeft

 

[mumps]

If I understood you correctly, this code will delete the "Digitizer" column and the column to the right.

Sub DelCol()
    Dim rng1 As Range
    With Sheets("Sheet1").Rows(1)
        Set rng1 = .Find(What:="Digitizer", _
                After:=.Cells(.Cells.Count), _
                LookIn:=xlValues, _
                LookAt:=xlWhole, _
                SearchOrder:=xlByRows, _
                SearchDirection:=xlNext, _
                MatchCase:=False)
        If Not rng1 Is Nothing Then
            Columns(rng1.Column).Resize(, 2).EntireColumn.Delete
        End If
    End With
End Sub

 

[doncarp]

You understood exactly what I needed. I did not have a chance to test it until this morning. I changed With Sheets("Sheet1").Rows(1) to With ActiveSheet.Rows(1) and it worked perfectly. You are amazing. Thank you.

 

[mumps]

My pleasure.