Delete files of a specific type in subfolders

[hendersam]

I have this vba code that deletes files of a specific type ("File") from the path indicated by the range name ("TMPath"):

Sub JunkFiles()

fPath = [TMPath]

Set fso = CreateObject _
("Scripting.FileSystemObject")

Set folder = fso.GetFolder(fPath)

For Each file In folder.Files

If fso.GetFile(file).Type = "File" Then
file.Delete
End If

Next

Set folder = Nothing
Set fso = Nothing
​

End Sub

I want to delete these files from all subfolders within the specified folder (fPath). How can this code be modified to loop through all subfolders of this folder?

Thanks,

Sam

 

[GTO]

Not well tested, but I think:

Option Explicit
    
Sub exa6()
Dim fso     As Object '<--- FileSystemObject
Dim fsoFol  As Object '<--- Folder
    
    Set fso = CreateObject("Scripting.FileSystemObject")
    ' Change ThisWorkbook.Path to suit
    Set fsoFol = fso.GetFolder(ThisWorkbook.Path)
    
    Call DelFiles(fso, fsoFol)
End Sub
    
Function DelFiles(oFSO As Object, Fol As Object)
'Dim Fil As File, oFol As Folder
Dim Fil As Object, oFol As Object
    For Each Fil In Fol.Files
        If Fil.Type = "Microsoft Word Document" Then
            Fil.Delete
        End If
    Next
    
    For Each oFol In Fol.SubFolders
        Call DelFiles(oFSO, oFol)
    Next
End Function