Delete Row Based On Multiple Factors

[Nanogirl21]

Hi, can someone please help me with a macro. I am trying to delete a row if it does not contain:


1 in column M and 3 in column N
OR
1 in column O and 3 in column P
OR
1 in column Q and 3 in column R
OR
1 in column S and 3 in column T
OR
1 in column U and 3 in column V
OR
1 in column W and 3 in column R


The range of data is from A7:AF:500.


Thank you.

 

[Joe4]

So, are you saying that if ANY of those 6 conditions are met, it should NOT be deleted, otherwise delete it?

Also, do you have a typo in your last condition?

1 in column W and 3 in column R

If it was consistent with the others, it would be:

1 in column W and 3 in column X

 

[Joe4]

If my assumptions are correct, this VBA code should do what you want:

Sub MyDeleteRows()


    Dim myRow As Long
    Dim myCount As Long
    Dim myCond As Long
    
    Application.ScreenUpdating = False
    
'   Loop through all rows backwards
    For myRow = 20 To 7 Step -1
'       Reset counter
        myCount = 0
'       Loop through 6 conditions and add one to counter if condition is met
        For myCond = 1 To 6
            If Cells(myRow, (myCond * 2) + 11) = 1 And Cells(myRow, (myCond * 2) + 12) = 3 Then
                myCount = myCount + 1
            End If
        Next myCond
'       If no conditions are met, delete the row
        If myCount = 0 Then Rows(myRow).Delete
    Next myRow
    
    Application.ScreenUpdating = True
    
End Sub