delete row macro question....

[mdcampbell1]

vb code question. i am trying to understand how to get a macro using vb to:
if i have a column of numbers, go through the whole column and identify any number that is less than say 10,000 and then select the entire row that number is on and delete the entire row. continue the process through the entire column. also, some cells in the column will be blank (delete), words (delete), and symbols such as # (delete).

i'm a relative novice here so any help would be appreciated.

Thanks,
MDC

 

[VoG]

Something like

Sub dl()
Dim lastrow As Long, MyCol As Integer, i As Integer, x As Variant
Application.ScreenUpdating = False
Application.Calculation = xlManual
MyCol = 1 ' change to suit
lastrow = Cells(Rows.Count, MyCol).End(xlUp).Row
For i = lastrow To 1 Step -1
    x = Cells(i, MyCol).Value
    If x < 10000 Or Not IsNumeric(x) Or x = "" Then Cells(i, MyCol).EntireRow.Delete
Next i
Application.ScreenUpdating = True
Application.Calculation = xlAutomatic
End Sub

Edit: changed lastrow= to refer to MyCol.

 

[brian.wethington]

Does something like this do the trick... I am assuming that your first line of data is headers and I am checking column A in this code

Sub Test()
Dim lastrow As Long, firstrow As Long, r As Long, Ce As Range

Application.ScreenUpdating = False
With ActiveSheet.UsedRange
    firstrow = .Cells(1).Row + 1
    lastrow = .Cells(.Cells.Count).Row
End With

For r = lastrow To firstrow Step -1
    Set Ce = Cells(r, 1)
    If (Not IsNumeric(Ce.Value)) Or (Ce.Value < 10000) Then Ce.EntireRow.Delete
Next r
Application.ScreenUpdating = True

End Sub

 

[mdcampbell1]

thanks for the help!