Delete sheet based on cell value

[PCTech]

I have a worksheet that I need the keep clean. In column A is a value that has a sheet with the same name. What I would like to do is, if there is an X in column F, delete the sheet that column A in the same row refers to, and then delete that row.
Will someone please help?
Thanks,

 

[HalfAce]

Hello PCTech,
See if something like this doesn't get you started.

Sub DeleteSheets()
Dim LstRw&, ShtName&
With Application
  .DisplayAlerts = False
  .ScreenUpdating = False

  '''/// Change 'Sheet1' to the real name of your sheet _
         containing the list of sheet names in column A.
  With Sheets("Sheet1")
    LstRw = .Cells(Rows.Count, "A").End(xlUp).Row
    For ShtName = LstRw To 1 Step -1
      If .Cells(ShtName, "F").Value = "X" Then
        On Error Resume Next
        Sheets(.Cells(ShtName, "A").Value).Delete
        If Not Err.Number = 0 Then
          MsgBox "There is no sheet named " & .Cells(ShtName, "A").Value & _
                 " to delete.", , "Sheet Deletion Error"
          Err.Clear
          GoTo SkipThisOne
        End If
        .Rows(ShtName).EntireRow.Delete
      End If
SkipThisOne:
    Next
  End With

  .ScreenUpdating = True
  .DisplayAlerts = True
End With
End Sub

Hope it helps. Let us know if it doesn't. (. . . and why. :wink: )

 

[PCTech]

The concept is correct. For every X in column F, I get the message box telling me there is no sheet named 86651. Which is the first one it comes to. It does that with all the X's. I did change the format in the column to text and I get the same error.
What else should I try?

UPDATE. It works on all new sheets I create.

Thanks for your help.

 

[HalfAce]

Ahh, sheets named with numeric values instead of text.
(I should've though of that.) Try changing this line from:
Sheets(.Cells(ShtName, "A").Value).Delete
to:
Sheets(.Cells(ShtName, "A").Text).Delete

This way it shouldn't matter what the sheet names are or how the column is formatted.

Does that help?

 

[PCTech]

Beautiful, Thank you very much.