Deleting 52k records by value in column A

[FryGirl]

I have a worksheet with which fills at almost 300k rows and out to column AA. I need to delete all the 2014 records which are about 53k. I've used a macro to filter by column A and used the notoriously slow looping, but both of these lockup and or after ten minutes I stopped the macro. I'm using a test sheet to see if I can get this working, but of course will have to do this on the real workbook when done. Here is what I tried. Any suggestions.

Sub Del2014()
Dim LR As Long, i As Long
LR = Range("A" & Rows.Count).End(xlUp).Row
TurnEverythingOff
On Error GoTo Skip
For i = LR To 1 Step -1
If Range("A" & i).Value = 2014 Then Rows(i).Delete
Next i
Skip:
TurnEverythingOn
End Sub

Sub TurnEverythingOff()
With Application
.Calculation = xlCalculationManual
.EnableEvents = False
.DisplayAlerts = False
.ScreenUpdating = False
End With
End Sub

Sub TurnEverythingOn()
With Application
.Calculation = xlCalculationAutomatic
.EnableEvents = True
.DisplayAlerts = True
.ScreenUpdating = True
End With
End Sub

 

[Fluff]

Are the 2014 record in consecutive cells, or spread throughout the column?
If the latter, are you happy to sort the data?

 

[FryGirl]

They are consecutive.

 

[Fluff]

Ok, how about

Sub Frygirl()
   With ActiveSheet
      .Range("A1").AutoFilter 1, "2014"
      .AutoFilter.Range.Offset(1).EntireRow.Delete
      .AutoFilterMode = False
   End With
End Sub

 

[FryGirl]

Thanks Fluff...That works great.

 

[jolivanes]

Either one of these should do what you want also if the values are consecutive.

Sub Maybe_A()
With Sheets("Sheet1").Columns(1)
    .Range(.Find(2014, , , 1, , 1), .Find(2014, , , 1, , 2)).EntireRow.Delete
End With
End Sub

Sub Maybe_B()
    ActiveSheet.Columns(1).Range(Columns(1).Find(2014, , , 1, , 1), Columns(1).Find(2014, , , 1, , 2)).EntireRow.Delete
End Sub

 

[Fluff]

Thanks Fluff...That works great.

You're welcome & thanks for the feedback

 

[FryGirl]

Thank you jolivanes for this additional code

 

[jolivanes]

You're welcome.
Hope you can use it somewhere sometime
Good Luck