Dependable Dynamic Unique List

[qwertytrewq]

Hello, I have data from which i need to extract unique list. i have everything up and running but my data has lot more rows n columns and excel takes forever to calculate it. Please suggest way to simplify these formulas to cut back on processing time or any if there is other way to get the desired dynamic list then please suggest that too.

Column A

Column B

Column C

Column D

Column E

Column F

Column G

Column H

Column I

Column J

Column K

Column L

Column M

Column N

Column O

Row 1

Below is Sample Data

Below is Calculation step to get Unique Value in Sequence as in Sample Data

Below is Desired Dynamic List obtained from Sample Data

Row 2

Sample

Data related to the sample

Row 3

First Name

Last Name

data1

data2

data3

First Name

Last Name

data1

data2

data3

Row 4

John

Doe

x

y

z

John ; Doe

Jane ; Dou

John ; Dow

John

Dow

z

x

y

Row 5

John

Dow

z

x

y

John ; Dow

Jane ; Dow

John ; Dou

John

Dou

x

z

y

Row 6

John

Dou

x

z

y

John ; Dou

Jane ; Doe

John ; Doe

John

Doe

x

y

z

Row 7

John

Doe

y

z

x

John ; Doe

John ; Doe

Jane ; Doe

Jane

Doe

y

x

z

Row 8

Jane

Doe

y

x

z

Jane ; Doe

John ; Dou

Jane ; Dow

Jane

Dow

z

y

x

Row 9

Jane

Dow

z

y

x

Jane ; Dow

John ; Dow

Jane ; Dou

Jane

Dou

x

x

x

Row 10

Jane

Dou

x

x

x

Jane ; Dou

#VALUE!

#VALUE!

#N/A

#N/A

#N/A

Row 11

Jane

Dou

y

y

y

Jane ; Dou

#VALUE!

#VALUE!

#N/A

#N/A

#N/A

<tbody>
</tbody>

A4:E11 is raw data which will get updated from time to time.
K4:O11 is the desired data obtained.

A4:B4 is the data from which unique values to be extracted ( there are two repeats A7:B7 & A11:B11 , C4:E11 plays no role whatsover in deciding uniqueness)

G4:G11 combines A4:E11 to decide the Unique value ( I could find no other way to calculate this than to actually combine the two columns, ";" is there to later search and seperate the columns.

H4:H11 is where duplicate values are removed.

I4:I11 repeated the formula in H4:H11 to get the value in sequence.

K4:L11 is where the Value obtained from I4:I11 is seperated out in two columns as in Sample data.

M4:O11 respective Data from C4:E11 is Indexed Matched.


Formula in G4 : =A4&" ; "&B4
Formula in H4 : =IFERROR(LOOKUP(2,1/(COUNTIF($H$3:H3,$G$4:$G$11)=0),$G$4:$G$11),"")
Formula in I4 : =IFERROR(LOOKUP(2,1/(COUNTIF($I$3:I3,$H$4:$H$11)=0),$H$4:$H$11),"")
Formula in K4 : =LEFT(I4,SEARCH(" ; ",I4)-1)
Formula in L4 : =RIGHT(I4,LEN(I4)-SEARCH(" ; ",I4)-2)
Formula in M4 : =INDEX($C$4:$C$11,MATCH(1,INDEX((K4=$A$4:$A$11)*(L4=$B$4:$B$11),0,1),0))
Formula in N4 : =INDEX($D$4:$D$11,MATCH(1,INDEX((K4=$A$4:$A$11)*(L4=$B$4:$B$11),0,1),0))
Formula in O4 : =INDEX($E$4:$E$11,MATCH(1,INDEX((K4=$A$4:$A$11)*(L4=$B$4:$B$11),0,1),0))

Thanks for taking a look at this.

P.S. : Ignore the errors will use IFERROR later.

 

[Aladin Akyurek]

Re: Dependable Dynamic Unique List - Little help here

Care to post the desired end result?

 

[qwertytrewq]

Re: Dependable Dynamic Unique List - Little help here

Care to post the desired end result?

care to read the whole post?
i dont think my post could be any more informative than it already is....2nd line below table "K4:O11 is the desired data obtained" or in other words K4:O11 is the desired end result.

 

[Aladin Akyurek]

Re: Dependable Dynamic Unique List - Little help here

care to read the whole post?
i dont think my post could be any more informative than it already is....2nd line below table "K4:O11 is the desired data obtained" or in other words K4:O11 is the desired end result.

Book1
	A	B	C	D	E	G	H	I	J	K	L
1	First Name	Last Name	data1	data2	data3	6
2	John	Doe	x	y	z	Idx	First Name	Last Name	data1	data2	data3
3	John	Dow	z	x	y	1	John	Doe	x	y	z
4	John	Dou	x	z	y	2	John	Dow	z	x	y
5	John	Doe	y	z	x	3	John	Dou	x	z	y
6	Jane	Doe	y	x	z	5	Jane	Doe	y	x	z
7	Jane	Dow	z	y	x	6	Jane	Dow	z	y	x
8	Jane	Dou	x	x	x	7	Jane	Dou	x	x	x
9	Jane	Dou	y	y	y
Sheet1 (2)

In G1 control+shift+enter, not just enter:

=SUM(IF(FREQUENCY(MATCH($A$2:$A$9&"|"&$B$2:$B$9,$A$2:$A$9&"|"&$B$2:$B$9,0),ROW($A$2:$E$9)-ROW(INDEX($A$2:$E$9,1,1))+1),1))

In G3 control+shift+enter, not just enter, and copy down:

=IF(ROWS($G$3:G3)>$G$1,"",SMALL(IF(FREQUENCY(MATCH($A$2:$A$9&"|"&$B$2:$B$9,$A$2:$A$9&"|"&$B$2:$B$9,0),ROW($A$2:$E$9)-ROW(INDEX($A$2:$E$9,1,1))+1),ROW($A$2:$E$9)-ROW(INDEX($A$2:$E$9,1,1))+1),ROWS($G$3:G3)))

In H3 just enter, copy across to L3, and down:

=IF($G3="","",INDEX($A$2:$E$9,$G3,MATCH(H$2,$A$1:$E$1,0)))