Dynamic Userform to delete selected sheets

[bujaman]

I want to create a userform that will list all worksheets in a workbook with CheckBoxes next to each one. The user then can check the worksheets they wish to delete, and click the OK button to delete them. I have been able to create a userform that lists all the sheets, but that is about it. Any help would be awesome! Thanks!

 

[Domenic]

Maybe something like this...

1) Place a listbox on the userform.

2) In the Properties Window for the listbox, set the MultiSelect property to '1-fmMultiSelectMulti'.

3) In the Properties Window for the listbox, set the ListStyle property to '1-fmListStyleOption'.

4) Place the following code in the userform module (right-click the userform, and select 'View Code')...

Option Explicit

Private Sub CommandButton1_Click()
    Dim MyArray() As Variant
    Dim i As Long
    Dim Cnt As Long
    With Me.ListBox1
        Cnt = 0
        For i = 0 To .ListCount - 1
            If .Selected(i) Then
                Cnt = Cnt + 1
                ReDim Preserve MyArray(1 To Cnt)
                MyArray(Cnt) = .List(i)
            End If
        Next i
        If Cnt > 0 Then
            If Worksheets.Count > UBound(MyArray) Then
                Application.DisplayAlerts = False
                Worksheets(MyArray).Delete
                Application.DisplayAlerts = True
                Call UpdateSheetList
            Else
                MsgBox "A workbook must contain at least one visible sheet.", vbExclamation
            End If
        Else
            MsgBox "Please select one or more sheets for deletion...", vbExclamation
        End If
    End With
End Sub

Private Sub UserForm_Initialize()
    Call UpdateSheetList
End Sub

Private Sub UpdateSheetList()
    Dim wks As Worksheet
    With Me.ListBox1
        .Clear
        For Each wks In Worksheets
            .AddItem wks.Name
        Next wks
    End With
End Sub

Change the code names for the controls, accordingly. Also, note that the user can select more than one sheet for deletion.

 

[bujaman]

Thanks! I got it working perfectly. That is just what I was looking for.