Edit this macro so people dont save as "Type Here!"

[tonywatsonhelp]

Hi Everyone,
I have this macro to open the save as dialog box and save the document as a new name,

It works great except people keep saving it as the defualt wording (I know right!)
so i want to add a bit of macro that says if the name you are trying to save at is " " then dont let them,

please help if you can
here my macro

Sub SaveFile()

Dim FileName As Variant
FileName = Application.GetSaveAsFilename("Type New File Name Here", _
    "Excel files,*.xlsm", 1, "Select your folder and filename")

If TypeName(FileName) = "Boolean" Then
MsgBox "User cancelled", vbCritical, "File Not Saved!"
Exit Sub
End If

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''' THIS BIT DOES NOT WORK!
If FileName = "Type New File Name Here.xlsm" Then
MsgBox "Can't use this name, please try again", vbCritical, "File Not Saved!"
Exit Sub
End If
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''


ActiveWorkbook.SaveAs FileName

End Sub

thanks

Tony

 

[johnnyL]

Sub SaveFile()
'
    Dim UserFileName
    Dim FileName As Variant
'
    FileName = Application.GetSaveAsFilename("Type New File Name Here", _
    "Excel files,*.xlsm", 1, "Select your folder and filename")
'
    If TypeName(FileName) = "Boolean" Then
        MsgBox "User cancelled", vbCritical, "File Not Saved!"
        Exit Sub
    End If
'
    UserFileName = Mid(FileName, InStrRev(FileName, "\") + 1, InStrRev(FileName, ".") - InStrRev(FileName, "\") - 1)
'
    If UserFileName = "Type New File Name Here" Then
        MsgBox "Can't use this name, please try again", vbCritical, "File Not Saved!"
        Exit Sub
    End If
'
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
    ActiveWorkbook.SaveAs FileName
End Sub

 

[Fluff]

Another option

If InStr(1, FileName, "Type New File Name Here.xlsm", vbTextCompare) > 0 Then
MsgBox "Can't use this name, please try again", vbCritical, "File Not Saved!"
Exit Sub
End If

 

[tonywatsonhelp]

Thank you jonnyL this was great,
and thank you fluff for another option,
but work great
thanks
Tony

 

[johnnyL]

Your welcome @tonywatsonhelp

 

[Fluff]

Glad to help & thanks for the feedback.