Editing a VBA code to remove input box

[ladbroke]

I found a code online that works when done manually, but there is one little bit of it I'd prefer to change but I can't figure out what to remove to make it work. I've tried to study the code but to no avail. I've tried to break it down and see what works and what doesn't, but it breaks it.
Please help.

I want to remove the input box that asks what cell range I am wanting to select and basically ask it to select column CC (entire column that is) automatically without me needing to select it every time.

I imagine I am going to look silly but it really would be much appreciated.

Sub SelectCellsWithData()
Dim bCell As Range
Set myRange = Application.Selection
Set myRange = Application.InputBox("choose one range that you want to select:", "SelectCellsWithData", myRange.Address, Type:=8)
For Each myCell In myRange
    If myCell.Value <> "" Then
        If bCell Is Nothing Then
            Set bCell = myCell
        Else
            Set bCell = Union(bCell, myCell)
        End If
    End If
Next
If Not bCell Is Nothing Then
    bCell.Select
End If
End Sub

 

[ladbroke]

I've figured it out.
I was deleting more than I should have.

Sub SelectCellsWithData()
Dim bCell As Range
Set myRange = Application.Selection
Set myRange = Range("CC:CC")
For Each myCell In myRange
    If myCell.Value <> "" Then
        If bCell Is Nothing Then
            Set bCell = myCell
        Else
            Set bCell = Union(bCell, myCell)
        End If
    End If
Next
If Not bCell Is Nothing Then
    bCell.Select
End If
End Sub

 

[Michael M]

You don't need to Select anything to work with it !
And I wouldn't reference an entire column either....
Try

Sub SelectCellsWithData()
Dim myCell As Range, bcell As Range, lr As Long
lr = Cells(Rows.Count, "CC").End(xlUp).Row
For Each myCell In Range("CC2:CC" & lr)
    If myCell.Value <> "" Then
        If bcell Is Nothing Then
            Set bcell = myCell
        Else
            Set bcell = Union(bcell, myCell)
        End If
    End If
Next
If Not bcell Is Nothing Then
    bcell.Select
End If
End Sub

 

[DanteAmor]

to select column CC

Try this:

Sub selectCells()
  On Error Resume Next
  Range("CC:CC").SpecialCells(xlCellTypeConstants, 23).Select
End Sub