Emailing contents and placing in the body of the mail

[wigarth]

Hi!

Trying to make a vba that sends an array into the body of an email as an image.
The code i have provided here works great, but the ".body" text always comes below the picture somehow.

Is there a way to make it come on top?

Sub emailcharts()

    Dim ol As Outlook.Application
    Dim MyEml As Outlook.MailItem
    Dim doc As Word.Document
    Dim rng As Range
    
    Set rng = Sheets("Epost").Range("f4:o59")
    Set ol = New Outlook.Application
    Set MyEml = ol.CreateItem(olMailItem)

rng.Copy

MyEml.Body = vbCr & ThisWorkbook.Sheets("Epost").Range("H2").Value & " " & ThisWorkbook.Sheets("Epost").Range("I2").Value & vbCr & vbCr & _
"Dette er tallene så langt" & vbCr & vbCr

MyEml.Display
    Set doc = MyEml.GetInspector.WordEditor
    
    MyEml.To = ThisWorkbook.Sheets("Epost").Range("c6").Value
    MyEml.Subject = ThisWorkbook.Sheets("Epost").Range("H2").Value & " " & ThisWorkbook.Sheets("Epost").Range("I2").Value

doc.Range(0, 0).PasteAndFormat Type:=wdChartPicture

End Sub

 

[Domenic]

Try the following...

Sub emailcharts()

    Dim ol As Outlook.Application
    Dim MyEml As Outlook.MailItem
    Dim doc As Word.Document
    Dim rng As Range
    
    Set rng = Sheets("Epost").Range("f4:o59")
    Set ol = New Outlook.Application
    Set MyEml = ol.CreateItem(olMailItem)

    rng.Copy

    With MyEml
        .Display
        .To = ThisWorkbook.Sheets("Epost").Range("c6").Value
        .Subject = ThisWorkbook.Sheets("Epost").Range("H2").Value & " " & ThisWorkbook.Sheets("Epost").Range("I2").Value
        Set doc = .GetInspector.WordEditor
        doc.Range.PasteAndFormat Type:=wdChartPicture
        .HTMLBody = "<p>" & ThisWorkbook.Sheets("Epost").Range("H2").Value & " " & ThisWorkbook.Sheets("Epost").Range("I2").Value & "</p>" & _
                "<p>Dette er tallene så langt</p>" & .HTMLBody
    End With
    
End Sub

Hope this helps!

 

[wigarth]

Try the following...

Sub emailcharts()

    Dim ol As Outlook.Application
    Dim MyEml As Outlook.MailItem
    Dim doc As Word.Document
    Dim rng As Range
   
    Set rng = Sheets("Epost").Range("f4:o59")
    Set ol = New Outlook.Application
    Set MyEml = ol.CreateItem(olMailItem)

    rng.Copy

    With MyEml
        .Display
        .To = ThisWorkbook.Sheets("Epost").Range("c6").Value
        .Subject = ThisWorkbook.Sheets("Epost").Range("H2").Value & " " & ThisWorkbook.Sheets("Epost").Range("I2").Value
        Set doc = .GetInspector.WordEditor
        doc.Range.PasteAndFormat Type:=wdChartPicture
        .HTMLBody = "<p>" & ThisWorkbook.Sheets("Epost").Range("H2").Value & " " & ThisWorkbook.Sheets("Epost").Range("I2").Value & "</p>" & _
                "<p>Dette er tallene så langt</p>" & .HTMLBody
    End With
   
End Sub

Hope this helps!

Worked perfectly. Many thanks to you! Still dont understand how this specifies it to be on top, but my macro now works (Is it the " & .htmlbody!" at the end?)

 

[Domenic]

Yes, that's correct. Basically, the contents of .HTMLBody gets replaced with text AND whatever is already in .HTMLBody, which in this case is the picture.

Cheers!

 

[wigarth]

Thanks Again Domenic! You are a true lifesaver

 

[Domenic]

You're very welcome, I'm glad I could help.

Cheers!