empty cell copy paste macro

[Tonyk1051]

wasnt sure how to go about this but i need a macro for the instructions below

in column k if a cell has the word "out" and the cell in column O
is empty then change the current word in column M to unresolved

once the above rules have been executed then

any cells that are empty in column O copy the data from column N paste it in the corresponding empty cell in column O
and high light It yellow

FYI the amount of lines differ every day anywhere from 45k to 700k (sheet name is Page1)

 

[Z51]

Looping through 45k-700k rows might not be fast, so you may want to look into using arrays, but this should work.

Sub tonyk()
Dim i As Long, lastrow As Long
lastrow = Range("K" & Rows.Count).End(xlUp).Row

For i = 2 To lastrow
    If Cells(i, 11).Value = "out" And Cells(i, 15).Value = "" Then Cells(i, 13).Value = "Unresolved"
Next i

With Range("O2:O" & lastrow).SpecialCells(xlCellTypeBlanks)
    .FormulaR1C1 = "=RC[-1]"
    .Interior.Color = 65535
End With
End Sub

 

[bebo021999]

It tooks 27s for 1 milion rows of data
Does it annoy too much?

Option Explicit
Sub test()
Dim lr As Long, i As Long, k As Long, rng, arr(1 To 1048576, 1 To 1)
Dim t
t = Timer
lr = Cells(Rows.Count, "K").End(xlUp).Row
rng = Range("K1:P" & lr).Value
For i = 1 To lr
    If rng(i, 5) = "" Then
        If rng(i, 1) = "out" Then rng(i, 3) = "unresolved"
        rng(i, 5) = rng(i, 4)
        k = k + 1
        arr(k, 1) = "O" & i
    End If
Next
Range("K1:P" & lr).Value = rng
For i = 1 To k
    Range(arr(i, 1)).Interior.Color = vbYellow
Next
MsgBox Timer - t
End Sub

 

[Tonyk1051]

It tooks 27s for 1 milion rows of data
Does it annoy too much?

Option Explicit
Sub test()
Dim lr As Long, i As Long, k As Long, rng, arr(1 To 1048576, 1 To 1)
Dim t
t = Timer
lr = Cells(Rows.Count, "K").End(xlUp).Row
rng = Range("K1:P" & lr).Value
For i = 1 To lr
    If rng(i, 5) = "" Then
        If rng(i, 1) = "out" Then rng(i, 3) = "unresolved"
        rng(i, 5) = rng(i, 4)
        k = k + 1
        arr(k, 1) = "O" & i
    End If
Next
Range("K1:P" & lr).Value = rng
For i = 1 To k
    Range(arr(i, 1)).Interior.Color = vbYellow
Next
MsgBox Timer - t
End Sub

thanks bebo works perfect