error combining several ranges

[excelNewbie22]

hi,
how to fix the error in the end of #n/a ?

test
	C	D	E	F	G	H	I	J	K	L	M	N
2	1	2	3		1	2	3	4	7	8	9	#N/A
3	4	5	6
4	7	8	9
5
6
7
test

Cell Formulas
Range	Formula
G2:N2	G2	=LET(t,VSTACK(C2:E2,C2:C4,C4:E4),r,ROWS(t),s,SEQUENCE(r*COLUMNS(t),,0),rs,MOD(s,r)+1,cs,INT(s/r)+1,i,INDEX(t,rs,cs),TRANSPOSE(UNIQUE(SORT(i))))
Dynamic array formulas.

 

[Fluff]

How about

=LET(t,VSTACK(C2:E2,EXPAND(C2:C4,,3,""),C4:E4),r,ROWS(t),s,SEQUENCE(r*COLUMNS(t),,0),rs,MOD(s,r)+1,cs,INT(s/r)+1,i,INDEX(t,rs,cs),TRANSPOSE(UNIQUE(SORT(i))))

 

[excelNewbie22]

it works fluff,
but sometimes i need to add ranges, and i don't get how to add more, or delete some in case i'll need to,
so only if possible can it be in a way i will just write them with commas?
like C2:E2,C2:C4,C4:E4 ?

 

[Fluff]

Maybe

=LET(t,VSTACK(C2:E2,C2:C4,C4:E4),r,ROWS(t),s,SEQUENCE(r*COLUMNS(t),,0),rs,MOD(s,r)+1,cs,INT(s/r)+1,i,INDEX(t,rs,cs),TRANSPOSE(UNIQUE(SORT(FILTER(i,NOT(ISERROR(i)))))))

 

[excelNewbie22]

superb!
much obliged!

 

[Fluff]

You're welcome & thanks for the feedback.