Excel 2010 VBA: Insert Image into cell comment

[pujo]

I found this be searching the forum vba by VoG:
The line "ShapeRange.Fill" gives an error"Application-defined or object-defined error"
I did change the directory to one of my own, and still receive the error.
However, rather than open a directory, I would like to logic to open the folder dialog so that I could choose which image I want rather than auto selecting.
Can anyone assist me with this task?
Thanks,
Pujo

Sub yetanothe()Dim i As LongFor i = 10 To 100    With Range("B" & i)        .AddComment        .Comment.Text Text:="Owner:" & Chr(10) & ""        .Comment.ShapeRange.Fill.UserPicture "C:\Users\Owner\Pictures\IRUS Diagrams\40" & i - 9 & ".jpg"    End WithNext iEnd Sub</PRE>

 

[VBA Geek]

Sub AddImageToComment()
Dim myImage As Variant, myCell As Range


Set myCell = Range("A1") ' ---- [change the cell in which you wish to add the comment]
myImage = Application.GetOpenFilename("Images, *.jpg", , "Select a picture", , 0)


If Not TypeName(myImage) = "Boolean" Then
    If myCell.Comment Is Nothing Then
        myCell.AddComment
    End If
    With myCell.Comment
        .Shape.Fill.UserPicture PictureFile:=myImage
        .Visible = True
    End With
End If
End Sub

 

[pujo]

That works great. Thanks!
How do I incorporate this bit into the procedure?

For i = 10 To 100
    With Range("B" & i)
Next i

 

[VBA Geek]

That works great. Thanks!
How do I incorporate this bit into the procedure?

For i = 10 To 100
    With Range("B" & i)
Next i

Sub AddImageToComment()
Dim myImage As Variant, myCell As Range, rng As Excel.Range
Set myCell = Range("b10:b100") ' ---- [change the cell in which you wish to add the comment]
myImage = Application.GetOpenFilename("Images, *.jpg", , "Select a picture", , 0)
If Not TypeName(myImage) = "Boolean" Then
    For Each rng In myCell.Cells
        If rng.Comment Is Nothing Then
            rng.AddComment
        End If
        With rng.Comment
            .Shape.Fill.UserPicture PictureFile:=myImage
            .Visible = True
        End With
    Next rng
End If
End Sub