Excel and Vba: send mail via Outlook

[Nelson78]

Hello everybody.

Today I bumped into the site in the image.

First of all: what is it? Something named Webmail OWA, maybe?

Second: how can I approach the task of sending mail in an authomatic way, using an Excel macro?
(I just need some suggestions, I normally send mail via Microsoft Office Outlook 2007 and, having the credentials to get in manually, I suppose it is something similar).

Thank's in advance.

Nelson78

 

[portews]

Good tutorial here:
VBA Outlook

 

[Logit]

Another example, more advanced :

Option Explicit

Sub Mail_Selection_Range_Outlook_Body()
' You need to use this module with the RangetoHTML subroutine.
' Works in Excel 2000, Excel 2002, Excel 2003, Excel 2007, Excel 2010, Outlook 2000, Outlook 2002, Outlook 2003, Outlook 2007, and Outlook 2010.
' Thanks to Ron DeBruin and Microsoft for their examples  https://www.rondebruin.nl/
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail
    'Dim RangetoHTML
    Set rng = Nothing
    
    'cpypaste    '<-- Calls the macro cpypaste which copies/pastes all sheet ranges to Sheet 1 to be placed
                '<-- into email body. This range is then cleared at bottom of macro.
      
    'On Error Resume Next
    ' Only send the visible cells in the selection.
    'Set rng = Selection.SpecialCells(xlCellTypeVisible)
    ' You can also use a range with the following statement.
    Set rng = Sheets("Sheet1").Range("B4:J13").SpecialCells(xlCellTypeVisible)
    

    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected. " & _
               vbNewLine & "Please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = "To Email Here"
        .CC = ""        '<-- CC Email here
        .BCC = ""       '<-- BCC Email here
        .Subject = "This is the Subject line " & Sheets("Sheet1").Range("B5").Value
        
        .HTMLBody = "Dear :  " & "<br><br><br>" & _
                    "Please review this latest data : " & "<br><br>" & _
                    "" & RangetoHTML(rng) & "<br><br><br>" & _
                    "Let us know if we can provide any additional information or assistance." & "<br><br>" & _
                    "Sincerely, " & "<br><br>" & _
                    "John Doe"
            ' In place of the following statement, you can use ".Display" to
            .Display
            '.Send
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
    
    Sheets("Sheet1").Range("AA1:AP63").Clear
    Sheets("Sheet1").Range("A1").Select
    
    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)
    
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
 
    ' Copy the range and create a workbook to receive the data.
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        .Range("A1:J13").ColumnWidth = 5
        '.Range("B4:J13").Font = 9
        
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
 
    ' Publish the sheet to an .htm file.
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
 
    ' Read all data from the .htm file into the RangetoHTML subroutine.
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
 
    ' Close TempWB.
    TempWB.Close savechanges:=False
 
    ' Delete the htm file.
    Kill TempFile
 
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Download file : Internxt Drive

 

[Nelson78]

No.
Excuse me, probably I've not explained the situation in a clear way.

I don't have avalaibility of Microsoft Office Outlook.

At the moment, manually, I've to navigate Webmail OWA, login with credentials, and send mail.

It seems to me that the two solutions you have proposed, need Microsoft Office Outlook.

 

[Logit]

I am not familiar with Webmail OWA. There also isn't much on the internet concerning email with W OWA.
Hopefully someone else has accomplished this goal and can share their experience with you.

 

[NoSparks]

Perhaps Ron de Bruin's Sending mail from Excel with CDO would be adaptable