Excel VBA - Open Word Doc, Save in MS DOS Text Format, Quit Word

[JoeDBugger]

Using Excel VBA, I want to process all Word documents in the working directory saving them in text format. The processing will include: (1) open a Word document, (2) save that Word document in MS DOS text format, and (3) quit Word. The following VBA Macro is invoked for each Word document:

Sub ProcessWordDocument(ByVal psWorkbookCurrentWorkingDirectory As String, _
                        ByVal psNextFullChecklistFileName As String, _
                        ByVal psNextChecklistFileName As String)
 
    Dim wdApplication As Word.Application
    Dim wdDocument As Word.Document
 
    On Error Resume Next
    Set wdApplication = GetObject(, "Word.Application")
    If Err.Number <> 0 Then
        '----+----+----+----+----+----+----+----+----+----+----+----+
        '  Word is NOT already running
        '----+----+----+----+----+----+----+----+----+----+----+----+
        Set wdApplication = CreateObject("Word.Application")
    End If
    On Error GoTo 0
 
    Set wdDocument = wdApplication.Documents.Open(psWorkbookCurrentWorkingDirectory & "\" & psNextFullChecklistFileName)
 
    wdApplication.Visible = True
 
    wdDocument.SaveAs psWorkbookCurrentWorkingDirectory & "\" & psNextChecklistFileName & ".txt"
 
    wdDocument.Close
 
    wdApplication.Quit
 
    Set wdApplication = Nothing
    Set wdDocument = Nothing
 
End Sub    '  End Sub ProcessWordDocument

The problem with the VBA code is with the statement:

    wdDocument.SaveAs psWorkbookCurrentWorkingDirectory & "\" & psNextChecklistFileName & ".txt"

The resultant file contains "garbage," of course. I need some mechanism to indicate the "FileFormat" to the ".SaveAs".

Thanks,

 

[JoeDBugger]

I just answered my own question using the following statement instead of the one that didn't work:

    wdDocument.SaveAs Filename:=psWorkbookCurrentWorkingDirectory & "\" & _
                      psNextChecklistFileName & ".txt", _
                      FileFormat:=wdFormatText, LockComments:=False, Password:="", _
                      AddToRecentFiles:=True, WritePassword:="", ReadOnlyRecommended:=False, _
                      EmbedTrueTypeFonts:=False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
                      SaveAsAOCELetter:=False, Encoding:=1252, InsertLineBreaks:=False, _
                      AllowSubstitutions:=False, LineEnding:=wdCRLF

A big thanks to all who viewed my question but hadn't responded with the answer yet.