Excel VBA to hide columns based on cell value

[Stuepef]

I have 3 tabs within my workbook that I would like to hide columns based on cell value. The following code hides some of the columns, but I am looking for assistance to add the rest of the columns. Here is what I am looking for:

Hide Columns J:M if cell K18 is ""
Hide Columns N:Q if cell O18 is ""
Hide Columns R:U if cell S18 is ""
Hide Columns V:Y if cell W18 is ""
Hide Columns Z:AC if cell AA18 is ""
Hide Columns AD:AG if cell AE is ""

Current code:

Sub HideColumnsSummary()    
Dim wsMySheet As Worksheet
    Application.ScreenUpdating = False
    For Each wsMySheet In ThisWorkbook.Sheets
        Select Case wsMySheet.Name
        Case Is = "Summary 1", "Summary (2)", "Summary (3)"
            With wsMySheet
                If .Range("K18").Value = "" Then
                Columns("J:M").EntireColumn.Hidden = True
                Else
                Columns("J:M").EntireColumn.Hidden = False
            End If
        End With
    End Select
    Next wsMySheet
    Application.ScreenUpdating = True
End Sub

I am sure there is a better way to write this code so I am open to any suggestions.

Thanks!

 

[Fluff]

How about

Sub HideColumnsSummary()
Dim wsMySheet As Worksheet
   Application.ScreenUpdating = False
   For Each wsMySheet In Sheets(Array("Summary 1", "Summary (2)", "Summary (3)"))
      With wsMySheet
         .Columns("J:M").EntireColumn.Hidden = .Range("K18").Value = ""
         .Columns("N:Q").Hidden = .Range("O18").Value = ""
         .Columns("R:U").Hidden = .Range("S18").Value = ""
      End With
   Next wsMySheet
   Application.ScreenUpdating = True
End Sub

 

[Stuepef]

Works perfectly, thank you Fluff!

 

[Fluff]

Glad to help & thanks for the feedback

 

[Stuepef]

@Fluff - How would I change the code you provided to code names? The tab names update with other code I have:

For Each wsMySheet In Sheets(Array("Summary 1", "Summary (2)", "Summary (3)"))

Summary 1 -> Sheet6
Summary (2) -> Sheet7
Summary (3) -> Sheet8

 

[Fluff]

Like

   For Each wsMySheet In Sheets(Array(Sheet6.Name, Sheet7.Name, Sheet8.Name))

 

[Stuepef]

Great, thank you!

 

[Fluff]

You're welcome

 

[Please_H]

@Stuepef - Thanks for having posted this Question
@Fluff - Yo ma man here we are again... Love yo support Bro...Thank you...