Excel workbook to email issues

[Dan190984]

Hi all

I am currently running the following which is returning an e-mail to the desired recipient, however I need to add the current sheet to the email (preferably only cells b3:k41) in the body of the email.

Any help????

Sub Mail()<?xml:namespace prefix = o ns = "urn:schemas-microsoft-comfficeffice" /><o></o>
<o> </o>
Dim OutlookApp As Object<o></o>
Dim Mess As Object, Recip As String<o></o>
Recip = ['[file name.xlsx]sheet name!$G$43]<o></o>
Set OutlookApp = CreateObject("Outlook.Application")<o></o>
Set Mess = OutlookApp.CreateItem(olMailItem)<o></o>
With Mess<o></o>
.Subject = "Subject"<o></o>
.Body =
.Recipients.Add Recip<o></o>
.Send<o></o>
End With<o></o>
<o> </o>
End Sub<o></o>

 

[VoG]

See if this helps http://www.rondebruin.nl/mail/folder2/mail4.htm

 

[Dan190984]

Been searching through that and the internet in general for hours - may as well be in Swahili!

Really struggling with this and I think it is quite simple.

 

[VoG]

Try this

Sub Mail()

Dim OutlookApp As Object
Dim Mess As Object, Recip As String, rng As Range
Set rng = Range("B3:K41")
Recip = ['[file name.xlsx]sheet name!$G$43]
Set OutlookApp = CreateObject("Outlook.Application")
Set Mess = OutlookApp.CreateItem(olMailItem)
With Mess
    .Subject = "Subject"
    .HTMLBody = RangetoHTML(rng)
    .Recipients.Add Recip
    .Send
End With
End Sub


Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2010
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook
 
    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
 
    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
 
    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
 
    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
 
    'Close TempWB
    TempWB.Close savechanges:=False
 
    'Delete the htm file we used in this function
    Kill TempFile
 
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

I linked to the wrong page before - it should have been http://www.rondebruin.nl/mail/folder3/mail4.htm