Exclude specific sheets from a macro

[Klb1503]

Hi,

I have the macro below and it works ok, however it currently looks at all the worksheets in the workbook and I would like to exclude the last 5 worksheets - is there a way to do this please?

Thanks
Karen


Sub Hide_Columns_Containing_Value()
Application.ScreenUpdating = False

Dim WS As Worksheet
Dim X As Range

For Each WS In ThisWorkbook.Worksheets

WS.Activate

Cells.Select
Selection.EntireRow.Hidden = False
Selection.EntireColumn.Hidden = False
For Each X In ActiveSheet.UsedRange.Columns(1).Cells
If X.Value = "False" Then
X.EntireRow.Hidden = True
ActiveSheet.Range("A1").Select

End If

Next X

Next WS


Application.ScreenUpdating = True
End Sub

 

[Leith Ross]

Hello Klb1503,

You will need to use a conditional statement like IF Then or Select Case to test the current worksheet's name against a list of the worksheets to ignore.

 

[Norie]

Perhaps.

Sub Hide_Columns_Containing_Value()
Dim WS As Worksheet
Dim X As Range
Dim I As Long

    Application.ScreenUpdating = False
    
    For I = 1 To ThisWorkbook.Sheets.Count - 5

        Set WS = ThisWorkbook.Sheets(I)
        
        With WS

            With .Cells
                .EntireRow.Hidden = False
                .EntireColumn.Hidden = False
            End With
            
            For Each X In .UsedRange.Columns(1).Cells
                If X.Value = "False" Then
                    X.EntireRow.Hidden = True
                End If
            Next X
            
        End With

    Next I

    Application.ScreenUpdating = True
    
End Sub