Extract text before 1st space

[keith0528]

Greetings,

I'm trying to do some string manipulation. I have a string that contains both alpha and numeric data. I want to extract the first number from the string. The number can be anywhere from 4 to 6 digits long so my strategy is to grab everything before the first space.

Ex. "123456 found in WkSht 9999"

I want to extract "123456"

I have the string stored in a variable sVal.

I think it should look something like:

TicketNum = Left(sVal).Value, InStr(1, sVal), " ") - 1)

but ofcourse my syntax isn't correct. Need a little assistance.

thanks

 

[VBA Geek]

try

TicketNum = Left(sVal, InStr(1, sVal, " ") - 1)

 

[Joe4]

You have an issue with where you have placed your parends. Try:

TicketNum = Left(sVal, InStr(1, sVal, " ") - 1)

 

[runwest]

Try this:

Val(Left(sVal, InStr(sVal, " ") - 1))

 

[Joe4]

Val(Left(sVal, InStr(sVal, " ") - 1))

Just be careful if you use this method. It does NOT work the same way as the first two.
If you number begins with a leading zero, this last option will drop it, while the first two will not.
So which one you want to use depends on whether or not you want to drop the leading zero off of your number (if one exists).

 

[keith0528]

Just be careful if you use this method. It does NOT work the same way as the first two.
If you number begins with a leading zero, this last option will drop it, while the first two will not.
So which one you want to use depends on whether or not you want to drop the leading zero off of your number (if one exists).

Thanks Joe4 and VBAGeek. That is exactly what i was looking for. I was close but close don't cut it in code.


regards,
Keith

 

[keith0528]

Many thanks guys. That did the trick.

Keith

 

[iliauk]

I think all the above more elegant/short but if you wanted RegEx

Sub TestRegExp()
Dim WRng As Range
Dim cell As Range
Set WRng = Columns("A")
Set WRng = WRng.SpecialCells(Type:=xlCellTypeConstants, Value:=xlNumbers + xlTextValues)

For Each cell In WRng
    cell.Offset(0, 1).Value = RegExp(cell, "[0-9]+")
Next cell
End Sub


Function RegExp(ByVal WhichString As String, _
                        ByVal Pattern As String, _
                        Optional ByVal IsGlobal As Boolean = True, _
                        Optional ByVal IsCaseSensitive As Boolean = True) As String
Dim objRegExp As Object
Dim allMatches As Object
Set objRegExp = CreateObject("vbscript.regexp")
With objRegExp
    .Global = IsGlobal
    .Pattern = Pattern
    .IgnoreCase = Not IsCaseSensitive
End With
Set allMatches = objRegExp.Execute(WhichString)
RegExp = allMatches.Item(0)
End Function

 

[Scott Huish]

or maybe this:

TicketNum = Split(sval)(0)