extracting word that appears the most

[Patcheen]

How can i show what word appears the most ?

ive used =Mode(a4:50) but that only shows #N/A

example - from A4:a50
a
b
a
c
a
c
b
a

the word that appears the most is a so in cell B2 should be the letter A

 

[AlKey]

Array formula

=INDEX(A2:A9,MODE(IF(ISTEXT(A2:A9),MATCH(A2:A9,A2:A9,0))))

Must be entered with Ctrl+Shift+Enter

Excel 2016 (Windows) 32 bit
	A	B
1
2	a	a
3	b
4	a
5	c
6	a
7	c
8	b
9	a
Sheet7

 

[T. Valko]

Try this...

Data Range

	A​	B​
1​	a​	a​
2​	b​
3​	a​
4​	c​
5​	a​
6​	c​
7​	b​
8​	a​
9​	------​	------​

This array formula** entered in C1:

=INDEX(A1:A8,MODE(MATCH(A1:A8,A1:A8,0)))

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.

 

[Patcheen]

works a treat thank you but how would i adapt to ignore blank cells?

 

[T. Valko]

Try this version...

Data Range

	A​	B​
1​	a​	a​
2​
3​	b​
4​	a​
5​	c​
6​
7​	a​
8​	c​
9​	b​
10​
11​	a​
12​	------​

Array entered**:

=INDEX(A1:A20,MODE(IF(A1:A20<>"",MATCH(A1:A20,A1:A20,0))))

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.

 

[Aladin Akyurek]

works a treat thank you but how would i adapt to ignore blank cells?

Have you seen post #2? But there is more to worry about. There can be many letters which can be the most frequent occurring... Consider:

Row\Col	A​	B​
4​	a	5​
5​	b	2​
6​	a	MODE-LIST
7​	c	a
8​	a	b
9​	c
10​	b
11​	a
12​	a
13​	b
14​	b
15​	d
16​	b
17​
18​

In B4 control+shift+enter, not just enter:

=MAX(FREQUENCY(IF(1-($A$4:$A$50=""),MATCH($A$4:$A$50,$A$4:$A$50,0)),ROW($A$4:$A$50)-ROW($A$4)+1))

In B5 control+shift+enter:

=SUM(IF(FREQUENCY(IF(1-($A$4:$A$50=""),MATCH($A$4:$A$50,$A$4:$A$50,0)),ROW($A$4:$A$50)-ROW($A$4)+1)=$B$4,1))

In B7 control+shift+enter and copy down:

=IF(ROWS($B$7:B7)>$B$5,"",INDEX($A$4:$A$50,SMALL(IF(FREQUENCY(IF(1-($A$4:$A$50=""),MATCH($A$4:$A$50,$A$4:$A$50,0)),ROW($A$4:$A$50)-ROW($A$4)+1)=$B$4,ROW($A$4:$A$50)-ROW($A$4)+1),ROWS($B$7:B7))))

 

[T. Valko]

1-($A$4:$A$50="")

Why obfuscate the logic?

$A$4:$A$50<>""

Is both more logically sound and more efficient.

 

[T. Valko]

If there might be multiple entries that appear the most times and you're using Excel 2010 or later:

Data Range

	A​	B​
1​	E​	A​
2​	C​	B​
3​
4​	A​
5​	A​
6​
7​	D​
8​	B​
9​	B​
10​	F​
11​	------​	------​

This array formula** entered in B1:

=IFERROR(INDEX(A$1:A$10,INDEX(MODE.MULT(IF(A$1:A$10<>"",MATCH(A$1:A$10,A$1:A$10,0))),ROWS(B$1:B1))),"")

** array formulas need to be entered using the key
combination of CTRL,SHIFT,ENTER (not just ENTER).
Hold down both the CTRL key and the SHIFT key
then hit ENTER.

Copy down until you get blanks.