Filter function with Match as the criteria?

[helpneeded2]

I would like to set a filter with 2 different criteria, one of which would be if the the value in 1 column of each row, matches a value in a list of of values in a named list range. Is there a way to do this within the Filter formula function?

 

[Fluff]

Within the Filter function, yes it is, but you profile shows xl 2010. Have you upgraded, or are you talking about the AutoFilter?

 

[helpneeded2]

Within the Filter function, yes it is, but you profile shows xl 2010. Have you upgraded, or are you talking about the AutoFilter?

We are on Office 365 now and I'm quite enjoying the functionality of FILTER, SORT and UNIQUE. I'm still learning what is possible with these, including making dynamic arrays. I want one of my Filter includes to be the match against a name list (i.e. check if "apples" is one of the listed values contained with the "listFruits" named range from another tab.)

I also was unaware I recorded my version of excel on my profile, so thank you for mentioning that. That info is quite old now... as am I

 

[Fluff]

What is you current formula that you want to change?

 

[helpneeded2]

What is you current formula that you want to change?

Here is what I have done right now which is sort of a work around.

=LET(f,FILTER(INDEX(table_jackpotDataRaw,SEQUENCE(ROWS(table_jackpotDataRaw)),XMATCH(A1:Q1,table_jackpotDataRaw[#Headers])),(table_jackpotDataRaw[Date  Time]<>"")*(table_jackpotDataRaw[List Match]=FALSE)),IFERROR(f+0,f))

On my raw data sheet, I included a column that does the match and outputs true / false, so that I can test for it within the filer on my results tab, by adding in the include: (table_jackpotDataRaw[List Match]=FALSE). Instead of having this column on my raw data sheet, I want filter to check if the data on the row associated with the table_jackpotDataRow[Exec Code Destription] column is present in the named range transactionType_list

The current reference to table_jackpotDataRaw[List Match] is one of two columns that have formulas that are on my data sheet (which is formatted as a table), however I would rather not have either of these columns on that sheet (in case a user accidentally copies raw data over the formulas).

 

[Fluff]

Ok, how about

=LET(f,FILTER(INDEX(table_jackpotDataRaw,SEQUENCE(ROWS(table_jackpotDataRaw)),XMATCH(A1:Q1,table_jackpotDataRaw[#Headers])),(table_jackpotDataRaw[Date  Time]<>"")*(ISNUMBER(MATCH(table_jackpotDataRaw[Exec Code Destription],transactionType_list,0)))),IFERROR(f+0,f))