Find all days between two dates from Range help

[BalloutMoe]

Hello All, I have this Sheet that reads a csv file and what not, I have the Date ranges in K1 and L1. I am wondering is there a way to find the all the dates equal and between the two dates for each shop location?
I have 10 different shop locations and numerous employees for each. I would like to know if the employee was no there for example on 11/4/21. So loop each store, employee, and date, if not found then print something. Any help would be appreciated. Thank you

 

[Peter_SSs]

For the future: MrExcel has a tool called “XL2BB” that lets you post small samples of your data that will allow us to copy/paste it to our Excel spreadsheets, so we can work with the same copy of data that you are. Instructions on using this tool can be found here: XL2BB Add-in

Note that there is also a "Test Here” forum on this board. This is a place where you can test using this tool (or any other posting techniques that you want to test) before trying to use those tools in your actual posts.

Could you use something like this?
(My dates are in d/m/y format)

BalloutMoe.xlsm
	A	B		D							K	L	M	N	O	P
1	Shop	Employee		Date							24/10/2021	26/10/2021		Shop	Employee	Absent
2	Shop 1	Emp 1		24/10/2021										Shop 1	Emp 1	26/10/21
3	Shop 1	Emp 2		24/10/2021										Shop 1	Emp 2
4	Shop 1	Emp 1		25/10/2021										Shop 2	Emp 3	24/10/21, 26/10/21
5	Shop 1	Emp 2		25/10/2021										Shop 2	Emp 4	24/10/21
6	Shop 1	Emp 2		26/10/2021
7	Shop 2	Emp 3		25/10/2021
8	Shop 2	Emp 4		25/10/2021
9	Shop 2	Emp 4		26/10/2021
10	Shop 2	Emp 4		27/10/2021
Sheet1

Cell Formulas
Range	Formula
N1:O5	N1	=UNIQUE(A1:B10)
P2:P10	P2	=IF(N2="","",LET(s,SEQUENCE(L$1-K$1+1,,K$1),TEXTJOIN(", ",1,IF(COUNTIFS(A$2:A$10,N2,B$2:B$10,O2,D$2:D$10,s)=0,TEXT(s,"d/m/yy"),""))))
Dynamic array formulas.

 

[BalloutMoe]

For the future: MrExcel has a tool called “XL2BB” that lets you post small samples of your data that will allow us to copy/paste it to our Excel spreadsheets, so we can work with the same copy of data that you are. Instructions on using this tool can be found here: XL2BB Add-in

Note that there is also a "Test Here” forum on this board. This is a place where you can test using this tool (or any other posting techniques that you want to test) before trying to use those tools in your actual posts.

Could you use something like this?
(My dates are in d/m/y format)

BalloutMoe.xlsm
	A	B		D							K	L	M	N	O	P
1	Shop	Employee		Date							24/10/2021	26/10/2021		Shop	Employee	Absent
2	Shop 1	Emp 1		24/10/2021										Shop 1	Emp 1	26/10/21
3	Shop 1	Emp 2		24/10/2021										Shop 1	Emp 2
4	Shop 1	Emp 1		25/10/2021										Shop 2	Emp 3	24/10/21, 26/10/21
5	Shop 1	Emp 2		25/10/2021										Shop 2	Emp 4	24/10/21
6	Shop 1	Emp 2		26/10/2021
7	Shop 2	Emp 3		25/10/2021
8	Shop 2	Emp 4		25/10/2021
9	Shop 2	Emp 4		26/10/2021
10	Shop 2	Emp 4		27/10/2021
Sheet1

Cell Formulas
Range	Formula
N1:O5	N1	=UNIQUE(A1:B10)
P2:P10	P2	=IF(N2="","",LET(s,SEQUENCE(L$1-K$1+1,,K$1),TEXTJOIN(", ",1,IF(COUNTIFS(A$2:A$10,N2,B$2:B$10,O2,D$2:D$10,s)=0,TEXT(s,"d/m/yy"),""))))
Dynamic array formulas.

Thank you for the tip on the way to upload and ask a question. I tried your formula and it works perfectly. Thank you so much for your help

 

[Peter_SSs]

You're welcome. Thanks for the follow-up.