Find date of first day of specified week number

[DRSteele]

Can someone please help me?

I would like to enter a week number and have a formula report the date of the xth Monday or the day if it's a stub week. The stub week days should be week 1 and then the next Monday should be week 2.

I assembled this ugly formula, but I know there must be a better way.

MrExcel posts18.xlsx
	A	B	C	D	E	F
2			year
3		week begin	2017	2018	2019	2020
4	weeknum	1	Sun, Jan 01, 2017	Mon, Jan 01, 2018	Tue, Jan 01, 2019	Wed, Jan 01, 2020
5		2	Mon, Jan 02, 2017	Mon, Jan 08, 2018	Mon, Jan 07, 2019	Mon, Jan 06, 2020
6		3	Mon, Jan 09, 2017	Mon, Jan 15, 2018	Mon, Jan 14, 2019	Mon, Jan 13, 2020
7		4	Mon, Jan 16, 2017	Mon, Jan 22, 2018	Mon, Jan 21, 2019	Mon, Jan 20, 2020
8		40	Mon, Sep 25, 2017	Mon, Oct 01, 2018	Mon, Sep 30, 2019	Mon, Sep 28, 2020
9		53	Mon, Dec 25, 2017	Mon, Dec 31, 2018	Mon, Dec 30, 2019	Mon, Dec 28, 2020
10		54	Mon, Jan 01, 2018	Mon, Jan 07, 2019	Mon, Jan 06, 2020	Mon, Jan 04, 2021
weeknumbers

Cell Formulas
Range	Formula
C4:F10	C4	=IF(OR(WEEKDAY(DATE(C$3,1,1),2)=1,$B4=1),DATE(C$3,1,1)+7*($B4-1),(DATE(C$3,1,1)+MOD(8-WEEKDAY(DATE(C$3,1,1),2),7))+7*($B4-2))

 

[jasonb75]

First thing that came to mind

=WORKDAY.INTL(DATE(C$3,1,1),$B4-1,"0111111")

 

[DRSteele]

Jeepers creepers! How embarrassing. Thank you very much.

I struggled all afternoon for nothing. I hope I didn't brain my damage.

 

[jasonb75]

I hope I didn't brain my damage.

Done there, been that