fmMultiSelectMulti

[tony.reynolds]

i have a userform with a Listbox

the form has worked really well now i want to be able to select more than one of the options

Thats fine ive selected multiSelectMulti and i can now select multipule entries. but how ever dou you get from the list box which ones are selected?

The Listbox1.Value dosnt seem to be ther anymore??

Please enlighten me as to how to get the data even if it is a sequence number (like selections=1,3,7)

 

[VoG]

Try like this

For i = 0 To ListBox1.ListCount - 1
    If ListBox1.Selected(i) Then
        'the selected value is true if the item is selected
        MsgBox ListBox1.List(i) & " selected"
    End If
Next i

 

[GTO]

Check out .Selected and .List in vba help. A simple example with one commandbutton and one listbox, both using default names:

Option Explicit
    
Private Sub CommandButton1_Click()
Dim i As Long
Dim myString As String
    
    With Me.ListBox1
        If .ListCount > 0 Then
            For i = 0 To .ListCount - 1
                If .Selected(i) Then
                    myString = myString & vbLf & .List(i)
                End If
            Next
            MsgBox "You picked: " & myString
        End If
    End With
End Sub
Private Sub UserForm_Initialize()
    With Me.ListBox1
        .MultiSelect = fmMultiSelectExtended
        .List = Array("Item 1", "Item 2", "Item 3", "Item 4", "Item 5", "Item 6", "Item 7", "Item 8")
    End With
End Sub

 

[tony.reynolds]

Thanks heaps, both of you

I will go from there