Force InputBox to Select range in Column A

[aejaz7]

Sub SelectionbyBox()
 
    Sheets("Sheet1").Activate
    Dim myRange As Range
    On Error GoTo inputerror
    Set myRange = Application.InputBox(Prompt:= _
        "Select Range", _
        Title:="Range Selection", Type:=8)
     If myRange Is Nothing Then Exit Sub
    Else
        myRange.Select
           End If
    Selection.Copy
    Range("D12").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
        
inputerror:
       MsgBox "Please select Any Cell"
End Sub

It is Possible to force inputbox to Select range only in column A or set other column to not selectable or any formula to end code if range selection is not in column A

 

[mikerickson]

You could do it so that the range acted on is always in column A of the cells the user chose.

Sub SelectionbyBox()
    Dim myRange As Range

    Sheets("Sheet1").Activate
    
    On Error GoTo inputerror
    Set myRange = Application.InputBox(Prompt:= "Select Range", Title:="Range Selection", Type:=8)
    On Error Goto 0

    If myRange Is Nothing Then 
        Exit Sub: Rem Cancel Pressed
    Else
        Set myRange = myRange.EntireRow.Columns(1)
        Range("D12").Resize(myRange.Rows.Count, 1).Value = myRange.Value
    End If
Exit Sub
inputerror:
       MsgBox "Please select Any Cell"
End Sub

 

[Norie]

You can easily check if the range selected is in column A or not

If myRange Is Nothing Then Exit Sub

If myRange.Column = 1 And myRange.Columns.Count = 1 Then
    myRange.Copy 
    Range("D12").PasteSpecial Paste:=xlPasteValues
Else
    MsgBox "Please ensure you select a range in column A!"
End If

 

[aejaz7]

Thanks, It's working.