Form Button Click

[rpaulson]

Here is my code that runs then the user clicks a button on the form.

Sub Toggle(Button)
With Button
    If .BackColor = &H8000000F Then 'if its gray
            .BackColor = &H80FF80 'turn green
            .Font.Bold = True
            .Font.Size = 70
            .Left = .Left - 25
            .Width = .Width + 50
            .Top = .Top - 25
            .Height = .Height + 50
            
        ElseIf .Font.Bold = True Then .Font.Underline = True
            
        Else 'turn back to gray
            .BackColor = &H8000000F
            .Font.Bold = False
            .Font.Size = 30
             .Left = .Left + 25
            .Width = .Width - 50
            .Top = .Top + 25
            .Height = .Height - 50
            .Font.Underline = False
    End If
End With
End Sub


Private Sub CommandButton1_Click()
    Call Toggle(CommandButton1)
End Sub

When the user click it the first time it turns green
When the click it a second time it underline the text
when they click it a third time, I need it to go back to gray.

Then 3rd part is not working.

anyone know what I'm missing here?

Ross

 

[AlphaFrog]

On the 1st click, the button is gray so it does the first part of the IF. No problem.

The 2nd click, the button is not gray. The 1st part of the IF is skipped and the 2nd part is run because the font is Bold

ElseIf .Font.Bold = True Then .Font.Underline = True

The font Bold is not changed. So every time after that you will always have ElseIf .Font.Bold = True be TRUE. So you will always run the 2nd part of the IF on subsequent clicks.

On the second click, you should change the .Font.Bold to False or test if the font is underlined.

 

[Rasm]

or something like this - just different approach - but easy to add to as well as modify

With Button
    Select Case .BackColor
        Case &H8000000F
            your code
        Case &H80FF80
            your code
        Case &H8000000F
            your code        
    End Select
End With

 

[djreiswig]

Rasm--I don't think the third part of your select case would get run as the first part is the same.

This should work.

Sub Toggle(Button)
With Button
    If .BackColor = &H8000000F Then 'if its gray
        .BackColor = &H80FF80 'turn green
        .Font.Bold = True
        .Font.Size = 70
        .Left = .Left - 25
        .Width = .Width + 50
        .Top = .Top - 25
        .Height = .Height + 50
        
    ElseIf .Font.Bold = True And .Font.Underline = False Then 
        .Font.Underline = True
        
    Else 'turn back to gray
        .BackColor = &H8000000F
        .Font.Bold = False
        .Font.Size = 30
        .Left = .Left + 25
        .Width = .Width - 50
        .Top = .Top + 25
        .Height = .Height - 50
        .Font.Underline = False
    End If
End With
End Sub


Private Sub CommandButton1_Click()
    Call Toggle(CommandButton1)
End Sub

 

[Rasm]

ahhh - I did not know - I will keep that in mind for the future - thanks

 

[rpaulson]

djreiswig,

you solution works.

Thanks.

 

[djreiswig]

Glad to hear it worked for you.