Formula Checked - Resizing Image

[TryenErrorenGoodenLk]

Please Gurus,

Help me change this formula, I want the size of the image which is inserted is to be exactly the size I wanted (or automatically as big as the size of the cell). Thanks in advance

Sub INSERT_PICTURE_DIALOG()
    '---------------------------------------------------------------------------
    '- SELECTED CELL
    Dim MyCell As Range
    Set MyCell = ActiveCell
    '---------------------------------------------------------------------------
    '- EXCEL INSERT PICTURE DIALOG. **AUTOMATIC INSERTION**.
    rsp = Application.Dialogs(xlDialogInsertPicture).Show
    If rsp = False Then Exit Sub
    '---------------------------------------------------------------------------
    '- RESIZE PICTURE TO CELL. CHANGE ITS NAME. REFORMAT
    With MyCell
        .Value = MyFile         ' put the file name into the cell
        '-
        Selection.Name = "MyName"
        Selection.Top = .Top
        Selection.Left = .Left
        Selection.Width = .Width
        Selection.Height = .Height
        Selection.ShapeRange.PictureFormat.Brightness = 0.5 ' various formats available
        Selection.Placement = xlMoveAndSize ' move and size with cells
        Selection.PrintObject = True
        '-
        .Select                 ' change focus (selection) from picture to cell
    End With
    '--------------------------------------------------------------------------
    Beep
End Sub

 

[GWteB]

Something like this perhaps ...

Sub INSERT_PICTURE_DIALOG_r2()

    Const cBorder       As Double = 5       ' << change as required
    Const cLockRatio    As Boolean = True   ' << change as required
    
    Dim sPicture As String, pic As Picture
    
    sPicture = Application.GetOpenFilename("Pictures (*.gif; *.jpg; *.bmp; *.tif), *.gif; *.jpg; *.bmp; *.tif", , "Select Picture to Import")
    If sPicture = "False" Then Exit Sub
    Set pic = ActiveSheet.Pictures.Insert(sPicture)
    With pic
        .ShapeRange.LockAspectRatio = cLockRatio
        ActiveCell.Value = .Name
        If Not .ShapeRange.LockAspectRatio Then
            .Width = ActiveCell.MergeArea.Width - (2 * cBorder)
            .Height = ActiveCell.MergeArea.Height - (2 * cBorder)
        Else
            If .Width >= .Height Then
                .Width = ActiveCell.MergeArea.Width - (2 * cBorder)
            Else
                .Height = ActiveCell.MergeArea.Height - (2 * cBorder)
            End If
        End If
        .Top = ActiveCell.MergeArea.Top + cBorder
        .Left = ActiveCell.MergeArea.Left + cBorder
        .Placement = xlMoveAndSize
        .PrintObject = True
    End With
    
    Set pic = Nothing
End Sub