Formula for random yes or no, with fixed % of yes and no

[elmacay]

Hi all,

I'm looking for a formula for two things. The first is that I want to return a random yes or no for any record, based on a certain percentage of yes's. So for a 100 records, with that yes variable at 10%, I'd like to get exactly 10 times yes and 90 times no.

Then, for the 10% yes's, I'd like to return a random number between 1 and 12, and if possible with an exact proportion of 1/12 for each, although with the number of records, that won't be statistically significant.

The background is that there are 7,000 social housing apartments rented out, of which 10% of tenants will move out yearly, randomly divided over the 12 months.

Any help is greatly appreciated!

Cheers, elmacay

 

[shg]

Part 1:

	A​	B​	C​
1​	Pct​	10%​	B1: Input
2​	Rows​	20​	B2: =ROWS(B5:B24)
3​	Yeses​	2​	B3: =B1*B2
4​	Item​	Result​
5​	1​	No​	B5: =IF(RAND() < ($B$3 - COUNTIF(B$4:B4, "Yes")) / ROWS(B5:B$24), "Yes", "No")
6​	2​	No​
7​	3​	No​
8​	4​	Yes​
9​	5​	No​
10​	6​	No​
11​	7​	No​
12​	8​	No​
13​	9​	No​
14​	10​	No​
15​	11​	No​
16​	12​	No​
17​	13​	No​
18​	14​	No​
19​	15​	No​
20​	16​	No​
21​	17​	Yes​
22​	18​	No​
23​	19​	No​
24​	20​	No​

I don't understand Part 2.

 

[DanteAmor]

Consider the following. Assuming 1200 houses

Formulas

Cell	Formula
B1	=ROUNDDOWN(COUNT(B2:B1201)*0.1,0)
C1	=ROUNDDOWN(B1/12,0)

Values

Cell	Value
D1	0
E2	1

Formulas to copy down

Cell	Formula
B2	=RAND()
C2	=INDEX($A$2:$A$1201,RANK(B2,$B$2:$B$1201))
D2	=IF(D1<$B$1,D1+1,"")
E3	=IF(D3<>"",IF(COUNTIF($E$2:E2,E2)<$C$1,E2,E2+1),"")

In column C you have the house and in column E the month:

Excel Workbook
	A	B	C	D	E
1	LIST	120.000	10	0	Month
2	House1	0.21743826	House938	1	1
3	House2	0.79717274	House237	2	1
4	House3	0.07240526	House1115	3	1
5	House4	0.88980084	House114	4	1
6	House5	0.14352507	House1028	5	1
7	House6	0.43779275	House677	6	1
8	House7	0.34696654	House794	7	1
9	House8	0.8577083	House157	8	1
10	House9	0.46657688	House642	9	1
11	House10	0.5228115	House579	10	1
12	House11	0.38052232	House756	11	2
13	House12	0.38370236	House749	12	2
14	House13	0.24314565	House912	13	2
15	House14	0.00874328	House1184	14	2
108	House107	0.2854487	House863	107	11
109	House108	0.47592046	House636	108	11
110	House109	0.98669431	House11	109	11
111	House110	0.81205319	House220	110	11
112	House111	0.41658899	House716	111	12
113	House112	0.49668822	House605	112	12
114	House113	0.67130158	House402	113	12
115	House114	0.72468806	House335	114	12
116	House115	0.8429541	House176	115	12
117	House116	0.55480391	House545	116	12
118	House117	0.87106914	House138	117	12
119	House118	0.54412287	House557	118	12
120	House119	0.03514036	House1153	119	12
121	House120	0.73333774	House317	120	12
Hoja4

Check the example in the file
https://www.dropbox.com/s/9t993u24omavia1/house.xlsx?dl=0

 

[joeu2004]

=IF(RAND() < ($B$3 - COUNTIF(B$4:B4, "Yes")) / ROWS(B5:B$24), "Yes", "No")

That guarantees no more than B3 number of "yes" values.

It does not guarantee exactly B3 number of "yes" values.

The following is one example where there are no "yes" values. In fact, in one set of 2000 trails, the results were:

yes=0: 254 no=20: 254
yes=1: 954 no=19: 954
yes=2: 792 no=18: 792
total=2000
0.718750 sec

So it failed to produce exactly two "yes" values 60% of the time.

	B	C	D	E
1	10%
2	20
3	2
4
5	IF(C < D,"yes","no")<d,"yes","no")< td=""></d,"yes","no")<>	rand	(B3-COUNTIF)/B2
6	no	0.782508	0.100000	B6: =IF(C6<d6,"yes","no")< td=""></d6,"yes","no")<>
7	no	0.678749	0.100000	C6: =RAND()
8	no	0.573805	0.100000	D6: =($B$3-COUNTIF($B$5:B5,"yes"))/$B$2
9	no	0.177724	0.100000
10	no	0.134276	0.100000
11	no	0.552324	0.100000
12	no	0.753078	0.100000
13	no	0.355138	0.100000
14	no	0.207782	0.100000
15	no	0.855179	0.100000
16	no	0.818034	0.100000
17	no	0.254240	0.100000
18	no	0.790729	0.100000
19	no	0.446269	0.100000
20	no	0.509162	0.100000
21	no	0.575007	0.100000
22	no	0.375010	0.100000
23	no	0.454331	0.100000
24	no	0.641269	0.100000
25	no	0.565769	0.100000

<tbody>
</tbody>

 

[joeu2004]

Aarrgghh ! This forum mangles lines that have " < " without spaces around it. I fixed B5, but I didn't see E6 until it was too late to edit. I should be:
B6: =IF(C6 < D6, "yes", "no")

 

[shg]

That guarantees no more than B3 number of "yes" values.

It does not guarantee exactly B3 number of "yes" values.

I don't know what you did, but I would happily wager $1000 to your favorite charity that what I did gives exact results.

 

[joeu2004]

I don't know what you did, but [...] what I did gives exact results.

Yes, my bad! I did not notice the relative reference in your ROWS(B5:B$24). So if we get to B23 and there are zero "yes" values, we will have RAND() < 1, which is TRUE. And if we get to B24 and there is only one "yes" value, again we will have RAND() < 1.