Formula Help - racheting

[Excel1990]

I would really appreciate help with the following formula as I just can't get it to work.

For each failure during a month I get charged 10
If I fail three months in a row I get charged and extra 50%, so 15 per failure.

If I fail again in the next month I get an additional 50% on top, so it's now 22.5 per failure.

If I don't fail then it automatically goes back to being charged 10.

3 or more consecutive months of failure incur the 50% premium, increasing by 50% each failure.

	Jan	Feb	Mar
Failures	1	2

<tbody>
</tbody>

I need the formula to be in the total for the year column, totally all months, including any premiums for 3 consecutive failures.

Please help if you , I'm tearing my hair out with this!

 

[Eric W]

Welcome to the forum!

I don't blame you for pulling your hair out, this is a toughie! About the only way I see to do it via formulas is with a helper row. Consider this:

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1		Jan	Feb	Mar	Apr	May	Jun	Jul	Aug	Sep	Oct	Nov	Dec		YTD
2	Failures	1	2		1	2	3	1	0	1	1		2
3	Cost	10	30	0	10	30	67.5	33.75	0	10	15	0	20		226.25
Sheet7

Cell Formulas
Range	Formula
B3	=B2*CHOOSE(COLUMN(B2)-AGGREGATE(14,6,COLUMN($A2:A2)/(N(OFFSET($A2,0,COLUMN($A2:A2)-COLUMN($A2)))=0),1)+1,0,10,15,22.5,33.75,50.63,75.94,113.91,170.86,256.29,384.43,576.65,864.98)
O3	=SUM(B3:M3)

Put the B3 formula in and drag to the right. Then the O3 formula is a basic SUM. If you don't want to see the individual months, you can hide that row and just include the SUM in a location of your choosing.

I can vaguely picture a way to do it in one cell, but it would be enormously complicated. The other option would be to write a User-Defined Function in VBA which would not be too hard if you want to go that route.

 

[Eric W]

Looks like I had a slight goof, the formula should be:

=B2*CHOOSE(COLUMN(B2)-AGGREGATE(14,6,COLUMN($A2:A2)/(N(OFFSET($A2,0,COLUMN($A2:A2)-COLUMN($A2)))=0),1)+1,0,10,10,15,22.5,33.75,50.63,75.94,113.91,170.86,256.29,384.43,576.65)

The second month should also be 10.

 

[Excel1990]

Thank you so so so so much!

 

[Excel1990]

Looks like I had a slight goof, the formula should be:

=B2*CHOOSE(COLUMN(B2)-AGGREGATE(14,6,COLUMN($A2:A2)/(N(OFFSET($A2,0,COLUMN($A2:A2)-COLUMN($A2)))=0),1)+1,0,10,10,15,22.5,33.75,50.63,75.94,113.91,170.86,256.29,384.43,576.65)

The second month should also be 10.

If I had scenario like this but for 5 years (still split out with one column per month) and the premium was applied on an annual basis, how could I do that.

I would need to include a sum of the 12 months into the formula. So if the sum of year 1 is over 0, and the sum of year 2 is over 0, then the sum of year 3 will incur a 50% premium?

 

[Eric W]

I think you'd want to make a summary table like this:

Book1
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1		Jan	Feb	Mar	Apr	May	Jun	Jul	Aug	Sep	Oct	Nov	Dec	Jan	Feb	Mar	Apr
2	Failures	1	2		1	2	3	1	0	1	1		2	1
3
4	Years	1	2	3	4	5		Total
5	Total	14	6	0	5	17
6	Fee	140	60	0	50	170		420
Sheet1

Cell Formulas
Range	Formula
B5	=SUM(INDEX(2:2,(COLUMNS($B2:B2)-1)*12+2):INDEX(2:2,(COLUMNS($B2:B2)-1)*12+13))
B6	=B5*CHOOSE(COLUMN(B2)-AGGREGATE(14,6,COLUMN($A5:A5)/(N(OFFSET($A5,0,COLUMN($A5:A5)-COLUMN($A5)))=0),1)+1,0,10,10,15,22.5,33.75,50.63,75.94,113.91,170.86,256.29,384.43,576.65,864.98)
H6	=SUM(B6:F6)

The amounts in row 2 go out for 60 columns (5 years). Then put the formula in B5 and copy to the right to get the annual totals. Then you can use the same basic formula from before in B6 (adapted for the different location) and copy that to the right.