Formula Help

[ststern45]

Hello,

I have a range of numbers in each cell that range from 0 through 9
Example:
A1=2
A2=4
A3=3
A4=5
A5=3
A6=5
A7=1
A8=6
A9=3
A10=4

I am looking to take the values in cell range A1:A10 and place the values in order as follows:
Values that appear the most to least.
So in the example above the result would be:
3334455216
The above calculations will be in cell range B1:B10
Next I want to take the 3334455216 and remove the duplicates.
So the result would be 345216
This would go in cell range C1:C6.

Example 1: Above
2435351634 (Cell range A1:A10) User entered values
3334455216 (Cell range B1:B10) Arrange in order-duplicate values that appear the highest 1st
345216 (Cell range C1:C6) Remove Duplicates from B1:B10

Example 2:
254925582 (Cell range A1:A9) User entered values
222555498 (Cell range B1:B9) Arrange in order-duplicate values that appear the highest 1st
25498 (Cell range C1:C5) Remove duplicates from B1:B9

Example 3:
4165323 (Cell range A1:A7) User entered values
3341652 (Cell range B1:B7) Arrange in order-duplicate values that appear the highest 1st
341652 (Cell range C1:C6) Remove duplicate from B1:B7

Thank you in advance!!

 

[Fluff]

I stopped using 365. Sorry I did not update my profile.

Can you please do so, that way members do not waste their time creating a formula that won't work. Thanks

 

[Fluff]

Thanks for updating your profile.
With a couple of helpers

+Fluff v2.xlsm
	A	B	C	D	E
1
2	2	1	3	3	3
3	4	2	3	3	4
4	3	3	3	3	5
5	5	2	2	4	6
6	3	3	2	5	1
7	5	2	2	5	2
8	1	1	2	4
9	6	1	1	6
10	3	3	1	1
11	4	2	1	2
Main

Cell Formulas
Range	Formula
B2:B11	B2	=COUNTIFS(A:A,A2)
C2:C11	C2	=AGGREGATE(14,6,$B$2:$B$11,ROWS(C$2:C2))
D2:D11	D2	=INDEX($A$2:$A$11,AGGREGATE(14,6,(ROW($A$2:$A$11)-ROW(A$2)+1)/($B$2:$B$11=LARGE($B$2:$B$11,ROWS(D$2:D2))),COUNTIFS(C$2:C2,C2)))
E2:E11	E2	=IFERROR(INDEX($D$2:$D$11,AGGREGATE(15,6,(ROW($D$2:$D$11)-ROW($D$2)+1)/(ISNA(MATCH($D$2:$D$11,E$1:E1,0))),1)),"")

 

[ststern45]

Thank you for the new formulas.
They work great

 

[Fluff]

Glad we could help & thanks for the feedback.