Formula to remove initials from a name

[FlowersinExcel]

Hi all,
I've looked at other threads asking how to remove a middle initial from a name, and tried those formulas with no luck, so I want to ask here. How to I remove the initials from this list of first names?

Full Name	Last Name	First Name	First name that I want to appear
These are hard-coded	=LEFT(A3,FIND(", ",A3,1)-1)	=RIGHT(A3,LEN(A3)-FIND(", ",A3,1)-1)	?????
Kim, Ki Tae Rick	Kim	Ki Tae Rick	Ki Tae Rick
Kim, Sa Kee	Kim	Sa Kee	Sa Kee
Rodriguez Vasquez, Vanessa S	Rodriguez Vasquez	Vanessa S	Vanessa
Amador, Omar M	Amador	Omar M	Omar
Cruz, Ai	Cruz	Ai	Ai

Thanks so much!

 

[awoohaw]

will you ever have a double first name? This will not work with those:

mr excel questions 12.xlsm
	A	B	C	D
1	Full Name	Last Name	First Name	First name that I want to appear
2	These are hard-coded	=LEFT(A3,FIND(", ",A3,1)-1)	=RIGHT(A3,LEN(A3)-FIND(", ",A3,1)-1)	?????
3	Kim, Ki Tae Rick	Kim	Ki Tae Rick	Ki
4	Kim, Sa Kee	Kim	Sa Kee	Sa
5	Rodriguez Vasquez, Vanessa S	Rodriguez Vasquez	Vanessa S	Vanessa
6	Amador, Omar M	Amador	Omar M	Omar
7	Cruz, Ai	Cruz	Ai	Ai
Sheet22

Cell Formulas
Range	Formula
D3:D7	D3	=IF(ISNUMBER(FIND(" ",C3))=FALSE,C3,LEFT(C3,FIND(" ",C3)-1))

 

[awoohaw]

if you cannot have helper columns (C3):

=IF(ISNUMBER(FIND(" ",RIGHT(A3,LEN(A3)-FIND(", ",A3,1)-1)))=FALSE,RIGHT(A3,LEN(A3)-FIND(", ",A3,1)-1),LEFT(RIGHT(A3,LEN(A3)-FIND(", ",A3,1)-1),FIND(" ",RIGHT(A3,LEN(A3)-FIND(", ",A3,1)-1))-1))

 

[Peter_SSs]

Will you ever have names with 2 (or more) initials and, if so, is this what they would look like?
Amador, Omar M G
Amador, Omar M G H

 

[FlowersinExcel]

will you ever have a double first name? This will not work with those:

mr excel questions 12.xlsm
	A	B	C	D
1	Full Name	Last Name	First Name	First name that I want to appear
2	These are hard-coded	=LEFT(A3,FIND(", ",A3,1)-1)	=RIGHT(A3,LEN(A3)-FIND(", ",A3,1)-1)	?????
3	Kim, Ki Tae Rick	Kim	Ki Tae Rick	Ki
4	Kim, Sa Kee	Kim	Sa Kee	Sa
5	Rodriguez Vasquez, Vanessa S	Rodriguez Vasquez	Vanessa S	Vanessa
6	Amador, Omar M	Amador	Omar M	Omar
7	Cruz, Ai	Cruz	Ai	Ai
Sheet22

Cell Formulas
Range	Formula
D3:D7	D3	=IF(ISNUMBER(FIND(" ",C3))=FALSE,C3,LEFT(C3,FIND(" ",C3)-1))

Awoohaw, yes, I definitely have a lot of double first names, so I need something that will delete the M if the name is Amador, Omar M but keep all of Kim, Ki Tae Rick. On the up side, I can have helper columns, so I could do a formula that just works from the first name. I'd still need something that turns Omar M into Omar and Ki Tae Rick stays Ki Tae Rick. Any thoughts?

 

[FlowersinExcel]

Will you ever have names with 2 (or more) initials and, if so, is this what they would look like?
Amador, Omar M G
Amador, Omar M G H

Looking at my list of 200+ names right now, I don't think that happens. So let's say no, no double initials! Does that make it easier?

 

[Fluff]

How about

Fluff.xlsm
	A	B	C
1	Full Name	Last Name	First Name
2	Kim, Ki Tae Rick	Kim	Ki Tae Rick
3	Kim, Sa Kee	Kim	Sa Kee
4	Rodriguez Vasquez, Vanessa S	Rodriguez Vasquez	Vanessa
5	Amador, Omar M	Amador	Omar
6	Cruz, Ai	Cruz	Ai
Main

Cell Formulas
Range	Formula
B2:B6	B2	=LEFT(A2,FIND(",",A2)-1)
C2:C6	C2	=IF(MID(A2,LEN(A2)-1,1)=" ",REPLACE(LEFT(A2,LEN(A2)-2),1,LEN(B2)+2,""),REPLACE(A2,1,LEN(B2)+2,""))

 

[awoohaw]

So, unless I have a "double first name" lookup table, how would I know not to exclude Mary Lou, or Billy Bob, or Ki Tae Rick from being changed to Mary, Billy, or Ki.

 

[awoohaw]

How about

Fluff.xlsm
	A	B	C
1	Full Name	Last Name	First Name
2	Kim, Ki Tae Rick	Kim	Ki Tae Rick
3	Kim, Sa Kee	Kim	Sa Kee
4	Rodriguez Vasquez, Vanessa S	Rodriguez Vasquez	Vanessa
5	Amador, Omar M	Amador	Omar
6	Cruz, Ai	Cruz	Ai
Main

Cell Formulas
Range	Formula
B2:B6	B2	=LEFT(A2,FIND(",",A2)-1)
C2:C6	C2	=IF(MID(A2,LEN(A2)-1,1)=" ",REPLACE(LEFT(A2,LEN(A2)-2),1,LEN(B2)+2,""),REPLACE(A2,1,LEN(B2)+2,""))

Fluff, this is not my thread, so if it is inappropriate to ask, please ignore or delete the post.
But how does that formula not change "Sa Kee" to just "Sa"?

 

[Fluff]

It just looks to see if the penultimate character is a space.