Formula to split a value over 3 columns based on conditions

ScotIain76

New Member
Joined
Oct 26, 2021
Messages
1
Office Version
  1. 2019
Platform
  1. Windows
Good morning

I would appreciate any advice on how I can create a formula to split a value up into 3 separate columns.

I want to calculate the amounts due as I need to pay the first 10 metres @£10, the next 90 metres @ £10 and the remaining (if any) @ £1 with the maximum anyone can receive being £3000

Some values are <10m, <100m etc.

Hopefully my attached example makes sense
 

Attachments

  • FORMULA HELP.JPG
    FORMULA HELP.JPG
    86 KB · Views: 5

Excel Facts

Highlight Duplicates
Home, Conditional Formatting, Highlight Cells, Duplicate records, OK to add pink formatting to any duplicates in selected range.

hrayani

Well-known Member
Joined
Jul 23, 2010
Messages
1,291
Office Version
  1. 2016
Platform
  1. Windows
I am sure there must be an easier way of doing it but this is what I have come up with

see if this helps provided I have understood your requirements correctly

Book5
ABCD
1Meters10 @1090 @75Remaining M @ 1
2100.18 100 6,750 0
31515.9 100 6,750 1,416
427508.27 100 6,750 3,000
5100 100 6,750 -
62.13 21 -
70 - -
828.13 100 1,360 -
Sheet1
Cell Formulas
RangeFormula
B2:B8B2=IF(A2<=10,A2*10,10*10)
C2:C8C2=IF(A2-10<=0,"",IF(A2-10>90,90*75,(A2-10)*75))
D2:D8D2=IF(A2-100>3000,3000,IF(A2-100<0,0,A2-100))
 

Dave Patton

Well-known Member
Joined
Feb 15, 2002
Messages
5,062
Office Version
  1. 365
  2. 2010
Platform
  1. Windows
Why do you want the calculation over 3 columns?
Which rates are correct? Your narrative rates are different from the rates in the image.
N.B. You can post an extract of your sheet with the forum's tool XL2BB.
For just the result, use the SumProduct or arithmetic.

T202110b.xlsm
EFGHIJKL
2 1-1011-100Total075
3Meters751011010
4100.187509000.181,650.181,650.181001
51515.975090013503,000.003,000.00
627508.2775090013503,000.003,000.00
1e
Cell Formulas
RangeFormula
F4:F6F4=MIN(10,E4)*$F$3
G4:G6G4=(E4>10)*MIN(E4-10,100-10)*$G$3
H4:H6H4=(E4>100)*MIN(3000-SUM(F4:G4),(E4-100)*$H$3)
I4:I6I4=SUM(F4:H4)
J4:J6J4=MIN(3000,SUMPRODUCT(--(E4>$K$2:$K$4),E4-$K$2:$K$4,$L$2:$L$4-$L$1:$L$3))
 

Dave Patton

Well-known Member
Joined
Feb 15, 2002
Messages
5,062
Office Version
  1. 365
  2. 2010
Platform
  1. Windows
F4 does not require the Table of brackets and rates.
The Bracket data and Rate Differentials are named; see Formulas Name Manager.
Brackets are named aB Refers To: ={0;10;100}
Rate Differentials are named aR Refers To: ={75;-65;-9}

T202110b.xlsm
EF
1
2
3MetersPayment
4100.181,650.18
51,515.903,000.00
627,508.273,000.00
71,450.003,000.00
86.00450.00
1e
Cell Formulas
RangeFormula
F4:F8F4=MIN(3000,SUMPRODUCT(--(E4>aB),E4-aB,aR))
 
Learn Excel from Bill Jelen

Understanding data is crucial, and the easiest place to start is with Microsoft Excel.

Forum statistics

Threads
1,151,579
Messages
5,765,211
Members
425,265
Latest member
bishopc22

We've detected that you are using an adblocker.

We have a great community of people providing Excel help here, but the hosting costs are enormous. You can help keep this site running by allowing ads on MrExcel.com.
Allow Ads at MrExcel

Which adblocker are you using?

Disable AdBlock

Follow these easy steps to disable AdBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the icon in the browser’s toolbar.
2)Click on the "Pause on this site" option.
Go back

Disable AdBlock Plus

Follow these easy steps to disable AdBlock Plus

1)Click on the icon in the browser’s toolbar.
2)Click on the toggle to disable it for "mrexcel.com".
Go back

Disable uBlock Origin

Follow these easy steps to disable uBlock Origin

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back

Disable uBlock

Follow these easy steps to disable uBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back
Top