Formulas Shortening

[DailyCaffeine]

Good afternoon,

I was wondering if someone could help me shorten or change my formula to something easier to understand?
=SUMPRODUCT(('Tab 2'!$E$6:$P$6=$A$4)*('Tab 2'!$D$8:$D$135=$A11)*('Tab 2!$E$8:$P$135))

Tab 2 contains a list of products that needs to be sorted in Tab 1.
The formula first checks which column in Tab 2 E6:P6 have the same month in Tab 1 A4
It then checks which rows in Tab 2 D have the same category as Tab 1 A11
Finally, it combines all of the values with the same month and category in a cell in Tab 1


Tab 2 looks as below

A	B	C	D	E	F	G
----	----	----	Category	April 2022	May 2022	June 2022
----	----	----	Enhanced Services	1000	2000	3000

Tab 1 looks as below

April 2022
A	B
Category	Total
Enhanced Services	1000

 

[Fluff]

I doubt you will get anything shorter than that. And as for easier to understand, that's very subjective & we don't know your knowledge level.
That said I don't think you will get anything "simpler"

 

[DanteAmor]

I put a couple of images to be clearer the explanation
The first image is tab 2. The values in red, in this example, will be added:

This minisheet is Tab 1:

Dante Amor
	A	B
1
2
3
4	April 2022
10	Category	Total
11	Enhanced Services	5,415
Tab 1

Cell Formulas
Range	Formula
B11	B11	=SUMIF('Tab 2'!$D$8:$D$135,A11,INDEX('Tab 2'!$E$8:$P$135,0,MATCH($A$4,'Tab 2'!$E$6:$P$6,0)))

This part corresponds to the categories in column D that are equal to the value in cell D11:
!$D$8:$D$135,A11

This part corresponds to the sum range, but it only considers the column that matches the month, the column search is the range E6 to P6 and must match the value of A4:
INDEX('Tab 2'!$E$8:$P$135,0,MATCH($A$4,'Tab 2'!$E$6:$P$6,0)))

----- --
NOTE XL2BB:
For the future, it would help greatly if you could give us the sample data in a form that we can copy to test with.
MrExcel has a tool called “XL2BB” that lets you post samples of your data that will allow us to copy/paste it to our Excel spreadsheets, so we can work with the same copy of data that you are. Instructions on using this tool can be found here: XL2BB Add-in
Note that there is also a "Test Here” forum on this board. This is a place where you can test using this tool (or any other posting techniques that you want to test) before trying to use those tools in your actual posts.
----- --