GET THE "DATE" OF THE "NEXT" DAY OF THE WEEK

[JuicyMusic]

Help please,
How do I write the formula to get me the date of the NEXT WEDNESDAY OR FRIDAY OF ANY DATE? I've tried for an hour.


1) Column A has a specific date - Column B shows the DAY of that date.
2) Column C has a formula based on 2 criteria - and the results will always either be "Friday" or "Wednesday".

Criteria 1 for the formula in column C: For batches made on Saturday, Sunday, Monday, and/or Tuesday, taxes must be “settled” by the following Friday.
Criteria 2 for the formula in column C: For batches posted on Wednesday, Thursday, and/or Friday, taxes must be “settled” by the following Wednesday.

Formula in Column C:

=IF(A3="","",
IF(OR(B3="Wednesday",B3="Thursday",B3="Friday"),"Wednesday","Friday"))

I'm sorry that I'm not allowed to insert the XL2BB. My company won't let me. Thank you so much in advance.

 

[Eric W]

How about:

Book1
	A	B	C	D
1	Schedule B
2	Pay Date	Day of Week	Next "Must be settled by" Day	Next "Must be settled by" date
3	4/1/2021	Thursday	Wednesday	4/7/2021
4	4/2/2021	Friday	Wednesday	4/7/2021
5	4/5/2021	Monday	Friday	4/9/2021
6	4/6/2021	Tuesday	Friday	4/9/2021
7	4/8/2021	Thursday	Wednesday	4/14/2021
8	4/9/2021	Friday	Wednesday	4/14/2021
9	4/10/2021	Saturday	Friday	4/16/2021
Sheet6

Cell Formulas
Range	Formula
B3:B9	B3	=TEXT(A3,"dddd")
C3:C9	C3	=TEXT(D3,"dddd")
D3:D9	D3	=A3+CHOOSE(WEEKDAY(A3),5,4,3,7,6,5,6)

 

[Dave Patton]

T202105a.xlsm
	A	B	C
1
2	Tue 11-May-21	Tuesday	Fri 14-May-21
3	Wed 12-May-21	Wednesday	Wed 19-May-21
4	Fri 14-May-21	Friday	Wed 19-May-21
5
2c

Cell Formulas
Range	Formula
A2	A2	=TODAY()
B2:B4	B2	=A2
C2:C4	C2	=IF(WEEKDAY(A2,16)<5,WORKDAY.INTL(A2,1,"1111011"),WORKDAY.INTL(A2,1,"1101111"))

 

[JuicyMusic]

How about:

Book1
	A	B	C	D
1	Schedule B
2	Pay Date	Day of Week	Next "Must be settled by" Day	Next "Must be settled by" date
3	4/1/2021	Thursday	Wednesday	4/7/2021
4	4/2/2021	Friday	Wednesday	4/7/2021
5	4/5/2021	Monday	Friday	4/9/2021
6	4/6/2021	Tuesday	Friday	4/9/2021
7	4/8/2021	Thursday	Wednesday	4/14/2021
8	4/9/2021	Friday	Wednesday	4/14/2021
9	4/10/2021	Saturday	Friday	4/16/2021
Sheet6

Cell Formulas
Range	Formula
B3:B9	B3	=TEXT(A3,"dddd")
C3:C9	C3	=TEXT(D3,"dddd")
D3:D9	D3	=A3+CHOOSE(WEEKDAY(A3),5,4,3,7,6,5,6)

Well, that is the most interesting formula for dates I've ever seen. Absolutely neat and PERFECT RESULTS! SOLVED!
I'm reading it right now to understand it and get familiar with it. TY!

 

[JuicyMusic]

Dave

T202105a.xlsm
	A	B	C
1
2	Tue 11-May-21	Tuesday	Fri 14-May-21
3	Wed 12-May-21	Wednesday	Wed 19-May-21
4	Fri 14-May-21	Friday	Wed 19-May-21
5
2c

Cell Formulas
Range	Formula
A2	A2	=TODAY()
B2:B4	B2	=A2
C2:C4	C2	=IF(WEEKDAY(A2,16)<5,WORKDAY.INTL(A2,1,"1111011"),WORKDAY.INTL(A2,1,"1101111"))

Dave, I'm looking at your suggestion now. It is brilliant. I will use this one to because I can incorporate it on a different report. TY!

 

[Dave Patton]

Thanks for the feedback. Dave