Go to next empty cell on another sheet

[daniels012]

I want to write code that will go to an empty cell on another sheet within the range Order!E2:N2. It would be good if the code took me to E2 if it is empty. If not, It would move to F2 etc. etc until It got to N2.


Thank You,
Michael

 

[daniels012]

Also, I want to do this from a button.

Thank You,
Michael

 

[Von Pookie]

Try this:

Sub test()
Dim i As Integer

With Sheets("Order")
    If Application.CountA(Range("E2:N2")) < 10 Then
        For i = 5 To 14
            If .Cells(2, i) = "" Then
                Application.Goto .Cells(2, i)
                Exit For
            End If
        Next i
    Else
        MsgBox "No cells available"
    End If
End With

End Sub

 

[daniels012]

Thank You.
It works great for my purposes. I filled every cell to see if it would give me a message box, It did not. I actually did nothing at all. It really is not a big deal, because I have never had each cell filled in.

Thank You again,
Michael

 

[Von Pookie]

Ooops, that's probably because I just saw that I have a tiny error in the code. And I mean *tiny*

On this line:

If Application.CountA(Range("E2:N2")) < 10 Then

Add a period before the word Range. So you should have

If Application.CountA(.Range("E2:N2")) < 10 Then

Believe it or not, that makes a difference. Without the period, it was checking the cells on whatever the active sheet was--not the "Order" sheet. Now if you fill in all of the cells, you should get the message.

 

[daniels012]

Thank You again. That actually worked great. Could I some how have go to Cell E2 if there are no empty cells?
I like the idea of a message, then take me to E2 on the other page so I remove what is in this cell or make a change.

Thank You,
Michael

 

[daniels012]

Here is what I added and it seems to work fine.

With Sheets("What to Order")
If Application.CountA(.Range("E2:N2")) < 10 Then
For i = 5 To 14
If .Cells(2, i) = "" Then
Application.Goto .Cells(2, i)
Exit For
End If
Next i
Else
MsgBox "Need to make some room on the What to Order sheet to list the new job."
Application.Goto .Range("e2")
End If
End With
End Sub


Michael