Great than or equal to formula help

[easybpw]

Hi everyone,

Thanks in advance for the help. I'm trying to adapt the formula below to be a greater than or equal to.

=SUMIFS('Card Type Summary'!$E:$E,'Card Type Summary'!$C:$C,$B$2,'Card Type Summary'!$A:$A,"DEBIT CARD")

In B2 is a date and the formula above works as is. It is pulling the debit card data for the specific date in B2. But when I change the formula to below I get the entered too few arguments error that I can't solve.

=SUMIFS('Card Type Summary'!$E:$E,'Card Type Summary'!$C:$C>=$B$2,'Card Type Summary'!$A:$A,"DEBIT CARD")

How can I change the formula to accommodate what I need?

 

[fjns]

Hi, see this formula
=SUMIFS('Card Type Summary'!$E:$E,'Card Type Summary'!$C:$C,">="&$B$2,'Card Type Summary'!$A:$A,"DEBIT CARD")

 

[easybpw]

I actually tried that formula prior to posting in the forum with the result being -0- and I can't understand why. I don't know how to upload a snip of my worksheet on the forum to show.

 

[easybpw]

Here is my worksheet. Only concerned about column B formulas. They are the ones that don't work.

Copy of CC 11.9.22 REC STO26(16741).xlsx
	A	B	C	D	E	F
1	Store	Beginning Date	Ending Date
2		11/10/2022	11/10/2022
3
4
5	TENDERS	Sum of Processed Net Amount
6	AMEX	$ -	$ -	$ -	-
7	DEBIT CARD	$ -	$ -	$ -	-
8	DISCOVER	$ -	$ -	$ -	-
9	MASTERCARD	$ -	$ -	$ -	-
10	VISA	$ -	$ -	$ -	-
11		$ -
12	CREDIT CARD	$ -	$ -	$ -	-
13
14	TOTAL	$ -	$ -	$ -	$ -
15
16
Total

Cell Formulas
Range	Formula
C6	C6	=(SUMIFS(Booking!$M:$M,Booking!$B:$B,">="&$B$2,Booking!$B:$B,"<="&$C$2,Booking!$F:$F,"Tender Type: AMERICAN EXPRESS"))*-1
D12,D6:D10	D6	=(SUMIFS('Cashier Differences Report'!$J:$J,'Cashier Differences Report'!$G:$G,">="&$B$2,'Cashier Differences Report'!$G:$G,"<="&$C$2,'Cashier Differences Report'!$F:$F,A6)*-1)
E12,E6:E10	E6	=B6-C6+-D6
C7	C7	=(SUMIFS(Booking!$M:$M,Booking!$B:$B,">="&$B$2,Booking!$B:$B,"<="&$C$2,Booking!$F:$F,"Tender Type: DEBIT CARD"))*-1
C8	C8	=(SUMIFS(Booking!$M:$M,Booking!$B:$B,">="&$B$2,Booking!$B:$B,"<="&$C$2,Booking!$F:$F,"Tender Type: DISCOVER"))*-1
C9	C9	=(SUMIFS(Booking!$M:$M,Booking!$B:$B,">="&$B$2,Booking!$B:$B,"<="&$C$2,Booking!$F:$F,"Tender Type: MASTERCARD"))*-1
C10	C10	=(SUMIFS(Booking!$M:$M,Booking!$B:$B,">="&$B$2,Booking!$B:$B,"<="&$C$2,Booking!$F:$F,"Tender Type: VISA"))*-1
B6:B7	B6	=SUMIFS('Card Type Summary'!$E:$E,'Card Type Summary'!$C:$C,">="&$B$2,'Card Type Summary'!$A:$A,"DEBIT CARD")
B8:B12	B8	=SUMIFS('Card Type Summary'!$E:$E,'Card Type Summary'!$C:$C,">="&$B$2,'Card Type Summary'!$C:$C,"<="&$C$2,'Card Type Summary'!$A:$A,$A8)
C12	C12	=(SUMIFS(Booking!$M:$M,Booking!$B:$B,">="&$B$2,Booking!$B:$B,"<="&$C$2,Booking!$F:$F,"*CREDIT CARD"))*-1
B14:E14	B14	=SUM(B6:B12)

Named Ranges
Name	Refers To	Cells
'Card Type Summary'!_FilterDatabase	='Card Type Summary'!$A$12:$D$125	B6:B12

And this should be the data sheet

Copy of CC 11.9.22 REC STO26(16741).xlsx
	A	B	C	D	E
1	Product Code	Site City	Txn Date	Processed Rejected Amount	Processed Net Amount
2	VISA		11/05/2022	.00	226,532.44
3	VISA		11/06/2022	.00	177,442.14
4	VISA		11/08/2022	.00	85,186.77
5	VISA		11/04/2022	.00	98,851.35
6	VISA		11/07/2022	.00	70,952.77
7	VISA		11/10/2022	.00	56,087.92
8	VISA		11/09/2022	.00	62,761.57
9	DEBIT CARD		11/05/2022	.00	169,018.66
10	DEBIT CARD		11/06/2022	.00	125,111.01
11	DEBIT CARD		11/04/2022	.00	68,942.83
12	DEBIT CARD		11/08/2022	.00	56,062.66
13	DEBIT CARD		11/07/2022	.00	59,883.44
14	DEBIT CARD		11/09/2022	.00	42,050.88
15	DEBIT CARD		11/10/2022	.00	40,552.22
16	MASTERCARD		11/05/2022	.00	95,800.18
17	MASTERCARD		11/06/2022	.00	61,385.06
18	MASTERCARD		11/08/2022	.00	28,911.03
19	MASTERCARD		11/04/2022	.00	28,661.02
20	MASTERCARD		11/07/2022	.00	26,582.61
21	MASTERCARD		11/10/2022	.00	16,629.93
22	MASTERCARD		11/09/2022	.00	23,070.49
23	AMEX		11/05/2022	.00	65,320.67
24	AMEX		11/06/2022	.00	55,948.69
25	AMEX		11/04/2022	.00	23,476.16
26	AMEX		11/08/2022	.00	25,346.08
27	AMEX		11/07/2022	.00	22,092.27
28	AMEX		11/10/2022	.00	17,771.38
29	AMEX		11/09/2022	.00	17,763.87
30	DISCOVER		11/05/2022	.00	24,942.86
31	DISCOVER		11/06/2022	.00	11,897.87
32	DISCOVER		11/04/2022	.00	8,256.30
33	DISCOVER		11/08/2022	.00	4,827.05
34	DISCOVER		11/09/2022	.00	6,388.16
35	DISCOVER		11/10/2022	.00	2,948.73
36	DISCOVER		11/07/2022	.00	7,728.21
37	Total			.00	1,915,185.28
Card Type Summary

 

[fjns]

Hi, the formulas in the linked table work well. I wrote the amounts randomly on the Booking and CashierDifferencesReport worksheets. My table has almost exactly the same formulas as your table. I have only one idea, that maybe there is a formatting problem in your table.

The formulas used in the table:
B6:
=SUMIFS('Card Type Summary'!$E:$E,'Card Type Summary'!$C:$C,">="&$B$2,'Card Type Summary'!$A:$A,$A6) (Range: B6:B10,B12)
C6: =(SUMIFS(Booking!$M:$M,Booking!$B:$B,">="&$B$2,Booking!$B:$B,"<="&$C$2,Booking!$F:$F,"Tender Type: AMERICAN EXPRESS"))*-1
C7: =(SUMIFS(Booking!$M:$M,Booking!$B:$B,">="&$B$2,Booking!$B:$B,"<="&$C$2,Booking!$F:$F,"*"&A7))*-1 (Range: C7:C10,C12)
D6: =(SUMIFS('Cashier Differences Report'!$J:$J,'Cashier Differences Report'!$G:$G,">="&$B$2,'Cashier Differences Report'!$G:$G,"<="&$C$2,'Cashier Differences Report'!$F:$F,A6)*-1) (Range: D6:D10,D12)
E6: =B6-C6+-D6 (Range: E6:E10,E12)
B14: =SUM(B6:B12) (Range: B14:E14)

CardTypeTotal.xlsx