Help/Advice on VBA Input Box Code

[lewis94]

Hi All,

I wonder if anyone could help me tidy up the code below for an Input box and then the output from this

The code is shown below for an input project name.

Inputt = InputBox("Please enter a Main Project Title." & vbNewLine & vbNewLine & vbNewLine & "Example: Sample_Project_1" & vbNewLine & vbNewLine & vbNewLine & "Please note the use of underscore for project names" & vbNewLine & vbNewLine & "Thankyou", "Add New Project")
', "Enter Scheme Titles"
arr = Split(Inputt, ",")
If Inputt = " " Then

Exit Sub

What I want to do is use a similar Input box but be able to input text/project names without the underscore

Also how could I then output this to a line on a sheet, say cell Z7

 

[dmt32]

Hi,

If you want a choice between project name styles then I suggest make a function of the code & pass an argument to it to determine which style to use

Place following in a STANDARD module

Function GetInput(Optional ByVal WhichStyle As Long = 1) As String
    Dim strPrompt(1 To 2) As String
    Dim Entry             As Variant
   
    Const NewLine   As Variant = vbNewLine & vbNewLine & vbNewLine
   
    strPrompt(1) = "Please enter a Main Project Title."
    strPrompt(2) = strPrompt(1) & NewLine & "Example: Sample_Project_1" & NewLine & _
                   "Please note the use of underscore For project names" & NewLine & "Thankyou"
   
    Do
        Entry = InputBox(strPrompt(WhichStyle), "Add New Project")
        'cancel pressed
        If StrPtr(Entry) = 0 Then Exit Function
    Loop Until WhichStyle = 1 And Len(Entry) > 0 Or WhichStyle = 2 And InStr(1, Entry, "_") > 0
   
    GetInput = Entry
   
End Function

And then to call it from your code

Sub Mytest()
    Dim myproject As String

    myproject = GetInput(WhichStyle:=1)

    Worksheets("Sheet1").Range("Z7").Value = myproject
End Sub

Which style is displayed by entering

1 (default) for basic project name

2 for project name with underscore

Dave