Help changing code

[dee101]

I found this code to check for duplicates in column F, works fine if all the data is numbers, how can I change it to work if the data is numbers and letters?
Thought I could just remove the IsNumeric part but I can't make it work, this is being used in Excel 2003.
Thanks

Sub CheckForDuplicates()
    Dim dict As Object
    Dim LR As Long, i As Long, v As Variant, strResult As String

    Set dict = CreateObject("Scripting.Dictionary")

    With ActiveSheet
        LR = .Range("F" & .Rows.Count).End(xlUp).Row
        For i = 2 To LR
            If IsNumeric(Range("F" & i).Value) And WorksheetFunction.CountIf(Columns("F"), Range("F" & i).Value) > 1 Then

                If dict.Exists(.Range("F" & i).Value) Then
                    dict.Item(.Range("F" & i).Value) = dict.Item(.Range("F" & i).Value) & .Range("F" & i).Row & " / "
                Else
                    dict.Add .Range("F" & i).Value, .Range("F" & i).Row & " / "
                End If
            End If
        Next i
    End With

    For Each v In dict.keys
        strResult = strResult & "Duplicates: " & v & vbNewLine & "In Rows: " & _
                    Left(dict.Item(v), Len(dict.Item(v)) - 1) & vbNewLine & vbNewLine
    Next v

    If strResult = "" Then
        'MsgBox "No duplicates"
    Else
        MsgBox strResult, , "Duplicates"

    End If

End Sub

 

[Osvaldo Palmeiro]

Hi. Have you tried like this:

If WorksheetFunction.CountIf(Columns("F"), Range("F" & i).Value) > 1 Then

 

[Rick Rothstein]

Give this macro a try in place of the one you posted...

[table="width: 500"]
[tr]
	[td]Sub CheckForDuplicates()
  Dim X As Long, Data As Variant
  Data = Range("F2", Cells(Rows.Count, "F").End(xlUp))
  With CreateObject("Scripting.Dictionary")
    For X = 1 To UBound(Data)
      If Len(.Item(Data(X, 1))) = 0 Then
        .Item(Data(X, 1)) = vbLf & vbLf & "Duplicates: " & Data(X, 1) & vbLf & "In Rows: " & X
      Else
        .Item(Data(X, 1)) = .Item(Data(X, 1)) & " / " & X
      End If
    Next
    For X = 1 To UBound(Data)
      If Not .Item(Data(X, 1)) Like "* / *" Then .Remove Data(X, 1)
    Next
    MsgBox Mid(Join(.items), 3)
  End With
End Sub[/td]
[/tr]
[/table]

 

[dee101]

both work, THANKS