Help me to Fill in Max, Min, Average by code VBA

[nhnn1986]

Hi all

I have sheets("data") with data from column E to last column. Now I want to have macro to do in each row i (with i from 4 to last row)
Ai.value = Max(Di:lastcolumn)
Bi.value = Min(Di:lastcolumn)
Ci.value = Average(Di:lastcolumn

Please help me to do that, thanks./.

 

[DanteAmor]

Try this:

Sub Macro8()
    lr = Range("E" & Rows.Count).End(xlUp).Row
    lc = Cells(4, Columns.Count).End(xlToLeft).Column
    With Range("A4:A" & lr)
        .FormulaR1C1 = "=MAX(RC5:RC" & lc & ")"
        .Value = .Value
    End With
    With Range("B4:B" & lr)
        .FormulaR1C1 = "=MIN(RC5:RC" & lc & ")"
        .Value = .Value
    End With
    With Range("C4:C" & lr)
        .FormulaR1C1 = "=AVERAGE(RC5:RC" & lc & ")"
        .Value = .Value
    End With
End Sub

 

[nhnn1986]

Code worked, many thanks @DanteAmor

I have a question that: Do you have any suggess about:
For i = 4 to lr
Range("Ai") = FormulaR1C1 "=MAX(RC5:RC" & lc & ")"
Range("Bi") = FormulaR1C1 "=MIN(RC5:RC" & lc & ")"
Range("Ci") = FormulaR1C1 "=Average(RC5:RC" & lc & ")"
next i

 

[DanteAmor]

For it to work, it must be like this

Sub Macro9()
    lr = Range("E" & Rows.Count).End(xlUp).Row
    lc = Cells(4, Columns.Count).End(xlToLeft).Column
    For i = 4 To lr
        Range("A" & i).FormulaR1C1 = "=MAX(RC5:RC" & lc & ")"
        Range("B" & i).FormulaR1C1 = "=MIN(RC5:RC" & lc & ")"
        Range("C" & i).FormulaR1C1 = "=Average(RC5:RC" & lc & ")"
    Next i
End Sub