Help With Recorded Macro

[Dazzawm]

I recorded this Macro below on a file that removes filter then sorts by column C then A (has a title row in 1). I want to use it on files with different amount of rows, what needs changing please to accommodate this?

Sub Macro1()
'
' Macro1 Macro
'

'
    Cells.Select
    Selection.AutoFilter
    ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add2 Key:=Range( _
        "C2:C42906"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
        xlSortNormal
    ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add2 Key:=Range( _
        "A2:A42906"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
        xlSortNormal
    With ActiveWorkbook.Worksheets("Sheet1").Sort
        .SetRange Range("A1:AY42906")
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End Sub

 

[Fluff]

How about

Sub Dazzawm()
   With ActiveSheet
      If .AutoFilterMode Then .AutoFilterMode = False
   End With
   With Range("A1:AY" & Range("A" & Rows.Count).End(xlUp).Row)
      .Sort Range("C1"), xlAscending, Range("A1"), , xlAscending, , , xlYes
   End With
End Sub

 

[Dazzawm]

How about

Sub Dazzawm()
   With ActiveSheet
      If .AutoFilterMode Then .AutoFilterMode = False
   End With
   With Range("A1:AY" & Range("A" & Rows.Count).End(xlUp).Row)
      .Sort Range("C1"), xlAscending, Range("A1"), , xlAscending, , , xlYes
   End With
End Sub

Thanks

 

[Fluff]

You're welcome.