Help with remove rows base on duplicate column value script

[davidmg1982]

The script below does a good work removing the rows based on the duplicates found in column a, however, it removes the last line with the duplicate, what I need is to remove the first line of the dups found. I appreciate your help.

Column A
Value 1
Value 2 <- Remove
Value 2
Value 3<- Remove
Value 4
Value 3

Sub RemoveDupe()
Dim rCell As Range
Dim rRange As Range
Dim lCount As Long

Set rRange = Range("A1", Range("A" & Rows.Count).End(xlUp))
lCount = rRange.Rows.Count

For lCount = lCount To 1 Step -1
    With rRange.Cells(lCount, 1)
        If WorksheetFunction.CountIf(rRange, .Value) > 1 Then
            .EntireRow.Delete
        End If
    End With
Next lCount
End Sub

 

[Fluff]

How about

Sub davidmg()
   Dim Rng As Range
   Dim i As Long
   
   With CreateObject("scripting.dictionary")
      For i = Range("A" & Rows.Count).End(xlUp).Row To 1 Step -1
         If Not .Exists(Cells(i, 1).Value) Then
            .Add Cells(i, 1).Value, Nothing
         Else
            If Rng Is Nothing Then Set Rng = Rows(i) Else Set Rng = Union(Rng, Rows(i))
         End If
      Next i
   End With
   If Not Rng Is Nothing Then Rng.Delete
End Sub

 

[davidmg1982]

That works smoothly, thank you very much.

 

[Fluff]

You're welcome & thanks for the feedback.