Hiding Rows Based on Dropdown Selection

[PC132]

Hello,

Relatively new to the VBA function.
Working on building a checklist that automatically shows and hides specific rows based on the option selected from the dropdown.

The Dropdown options: "BOV, Off Market Flyer"

After searching a few forums below is the code:
---------------
Private Sub worksheet_change(ByVal Target As Range)
If Range("D15") = "BOV" Then
Rows("16:51").EntireRow.Hidden = False
Else
Rows("16:51").EntireRow.Hidden = True
End If

If Range("D15") = "Off Market Flyer" Then
Rows("52:54").EntireRow.Hidden = True
Else
Rows("52:54").EntireRow.Hidden = False

End If

End Sub
--------------
The macro seems to work, however, there is no change when either option is selected.

Please advice and Thank you in advance!

 

[Trebor76]

Hi PC132,

Try this:

Option Explicit
Private Sub worksheet_change(ByVal Target As Range)

    If Target.Address = "$D$15" Then

        With Application
            .ScreenUpdating = False
            .EnableEvents = False
        End With
    
        If Target.Value = "BOV" Then
            Rows("16:51").EntireRow.Hidden = False
        Else
            Rows("16:51").EntireRow.Hidden = True
        End If
        
        If Target.Value = "Off Market Flyer" Then
            Rows("52:54").EntireRow.Hidden = True
        Else
            Rows("52:54").EntireRow.Hidden = False
        End If
    
        With Application
            .EnableEvents = True
            .ScreenUpdating = True
        End With
        
    End If

End Sub

Regards,

Robert

 

[PC132]

Robert,

I appreciate the quick response!

The new code works perfectly!

Much appreciated

Thanks