hiding rows depending on drop down list

[pawwwd]

im looking for an easy way VBA to hide specific rows in excell, got three choices in a drop down list and depending of what I choose i want three different set of rows to be hidden.

If i choose "AM" i want to hide rows 30:48
if i choose "PM" i want to hide rows 16:29 and 41:48
if i choose "NS" i want to hide rows 16:40

 

[dave3009]

Right click the sheet tab and select "View Code". Paste in the below. Change B2 to the cell that holds your dropdown list.,

'************************************************************
'*                                                          *
'*  If i choose "AM" i want to hide rows 30:48              *
'*  if i choose "PM" i want to hide rows 16:29 and 41:48    *
'*  if i choose "NS" i want to hide rows 16:40              *
'*                                                          *
'*  Author: dave3009                                        *
'*  Date: 2022-09-27                                        *
'*                                                          *
'************************************************************

Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False                        'Turn off event listening
If Not Intersect(Target, Range("B2")) Is Nothing Then   'Check if the dropdown cell has changed
    Rows("16:48").Hidden = False                        'Unhide all the rows
    Select Case Target.Value                            'Select the case for the change and hide
        Case Is = "AM"                                  ' the relevant rows
            Rows("30:48").Hidden = True
        Case Is = "PM"
            Rows("16:29").Hidden = True
            Rows("41:48").Hidden = True
        Case Is = "NS"
            Rows("16:40").Hidden = True
    End Select
End If
Application.EnableEvents = True                         'Turn on event listening
End Sub

 

[pawwwd]

 

[dave3009]

You did not follow the instructions.

 

[pawwwd]

You did not follow the instructions.

my bad... its working now thanks!